sort_desc_len(L,S) :-
  findall(N-T,(member(T,L),atom_length(T,M),N is -M),LT),
  keysort(LT,ST),
  findall(T,member(_-T,ST),S).

то есть findall/3 реализует замыкания с помощью member/2. setof/3 позволит объединить первый вызов findall и keyort, но удалит дубликаты...

Обратите внимание, что atom_length/2 не может работать с процессором, совместимым с ISO. Строки в двойных кавычках — это списки кодов, а не атомов.

В любом случае, я согласен с тем, что Пролог довольно многословен, когда дело доходит до функционального программирования. Я думаю, причина в том, что у него реляционная модель данных.

В моем ответе в Твиттере на вопрос Пола Грэма используется библиотечный предикат Logtalk list::msort/3 и лямбда-выражение, вызывающее стандартный предикат ISO Prolog compare/3, и де фактический стандартный предикат length/2. Предполагая, что флаг double_quotes установлен на codes (наиболее переносимый параметр; фактически, единственный параметр, поддерживаемый некоторыми системами Prolog):

| ?- {types(loader)}.
yes

| ?- list::msort(
         [Order, List1, List2]>>(
             length(List1, N1), M1 is -N1,
             length(List2, N2), M2 is -N2,
             compare(Order, M1, M2)
         ),
         ["a", "bcd"",cd", "ef", "ghij"],
         Sorted
     ).
Sorted = [[98,99,100,34,44,99,100],[103,104,105,106],[101,102],[97]]
yes

При работе на поддерживаемых внутренних компиляторах Prolog, которые не предоставляют предикат length/2 в качестве встроенного предиката, вместо этого мы можем использовать:

| ?- {types(loader)}.
yes

| ?- list::msort(
         [Order, List1, List2]>>(
             list::length(List1, N1), M1 is -N1,
             list::length(List2, N2), M2 is -N2,
             compare(Order, M1, M2)
         ),
         ["a", "bcd"",cd", "ef", "ghij"],
         Sorted
     ).
Sorted = [[98,99,100,34,44,99,100],[103,104,105,106],[101,102],[97]]
yes

Как ни странно, это одно из самых переносимых решений, представленных на данный момент, работающее на 12 системах Prolog (т. е. на всех системах, поддерживаемых Logtalk).

Как заметил @CapelliC, реляционный язык всегда будет предоставлять более подробное решение по сравнению с функциональным языком.

Я просто думаю функционально:

По-видимому, предикатом для использования является predsort. Это на самом деле не ISO, а из library(list)

my_cmp(X,L,R) :- 
   atom_length(L,Llen),atom_length(R,Rlen),
   ((Llen < Rlen) -> X = '>' ;
    (Llen > Rlen) -> X = '<' ;
    X = '=').

sort_desc_len(L,S) :- predsort(my_cmp,L,S).

В зависимости от того, как вычисляется atom_length/2 (то есть в зависимости от того, нужно ли просто получить скрытое значение length, а не пройти по строке атома), это может быть довольно быстро.

:- begin_tests(sort_desc_len).
test(empty)      :- sort_desc_len([],[]).
test(nop)        :- sort_desc_len([aaa,bb,c],[aaa,bb,c]).
test(reverse)    :- sort_desc_len([a,bb,ccc],[ccc,bb,a]).
test(duplicates) :- sort_desc_len([a,bb,bb,ccc],[ccc,bb,a]).
test(stability)  :- sort_desc_len([i,j,k],[i,j,k]).
test(random)     :- sort_desc_len([a,xx,fg,hhh,jk],[hhh,xx,fg,jk,a]).
test(exercise)   :- sort_desc_len([a,bcd,ef,ghij],[ghij,bcd,ef,a]).
:- end_tests(sort_desc_len).

Итак, тесты I Herd U Liek...

?- run_tests(sort_desc_len).
% PL-Unit: sort_desc_len ....
ERROR: user://4:87:
        test stability: failed

ERROR: user://4:88:
        test random: failed

. done
% 2 tests failed
% 5 tests passed

К сожалению, predsort/3 удаляет дубликаты. Абсолютно должно быть predsort/4, указывающее, должны ли дубликаты исчезнуть или нет.

?- sort_desc_len([i,j,k],X).
X = [i].

?- sort_desc_len([a,xx,fg,hhh,jk],X).
X = [hhh, xx, a].

НЕУДАЧА.

Приложение

Менее шумно с использованием compare/3, как предложено в комментарии повторить.

Н.Б. compare/3 вызов с обменом левой и правой длин.

my_cmp(X,L,R) :- 
   atom_length(L,Llen),
   atom_length(R,Rlen),
   compare(X,Rlen,Llen).

sort_desc_len(L,S) :- predsort(my_cmp,L,S).

?- run_tests(sort_desc_len).
% PL-Unit: sort_desc_len ....
ERROR: user://1:20:
        test stability: failed

ERROR: user://1:21:
        test random: failed

. done
% 2 tests failed
% 5 tests passed
false.