Используйте SAS для подсчета количества субъектов, которым необходимы контрольные визиты до заданной даты.

Если вы создаете набор данных со строкой для каждой комбинации идентификатора участника и посещения, вы можете перейти к классификации каждого посещения, которое (еще) не было (пока) посещено. Это упрощает ручную проверку и подсчет различных посещений.

В приведенном ниже коде я классифицировал посещение как пропущенное, если его запланированная дата была более недели назад, и я классифицировал участника как вероятного выбывшего, если его последний визит был более года назад. Вы можете изменить эти правила.

Обратите внимание, что набор данных результата будет меняться со временем, поскольку даты сравниваются с today().

* Define test data;
data have;
Input id$ visit$ enrdate : mmddyy10. Vsdate : mmddyy10. ;
Format enrdate mmddyy10. Vsdate mmddyy10.; 
Cards;
ABC01 00 1/2/2020 1/2/2020
ABC02 00 5/16/2019 5/16/2019
ABC02 06 5/16/2019 11/12/2019
CDC01 00 8/20/2019 8/20/2019
CDC01 06 8/20/2019 2/16/2020
EFG01 00 5/20/2020 5/20/2020
EFG02 00 12/2/2018 12/2/2018
EFG02 02 12/2/2018 1/31/2019
EFG02 06 12/2/2018 5/31/2019
EFG02 12 12/2/2018 12/2/2019
EFG03 00 3/3/2019 3/3/2019
EFG03 12 3/3/2019 3/2/2020
GFF04 00 6/2/2019 6/2/2019
GFF04 06 6/2/2019     .
;
run;

* Define the planned visits;
data planned_visits;
Input visit$;
Cards;
00
06
12
18
24
;
run;

* List and categorize all visits for all participants;
proc sql;
   create table id_visit_list as 
      select a.id
            ,a.enrdate
            ,b.visit
            ,intnx('month',a.enrdate,input(b.visit,best.),'s') as planned_date format mmddyy10.
            ,c.vsdate
            ,case
               when not missing(vsdate) then "Visit attended"
               when calculated planned_date + 7 < today() then "Visit skipped"
               when calculated planned_date > '19AUG2021'D then "Visit after cut-off"
               when max(vsdate) + 365 < today() then "Likely drop-out"
               else "Scheduled visit"
            end as visit_status 
      from (select distinct id, enrdate from have) as a
      left join (select distinct visit from planned_visits) as b
         on 1
      left join have as c
         on a.id = c.id and b.visit = c.visit
      group by a.id
   ;
quit;

* Count number of scheduled visits;
proc sql;
   create table want as 
      select distinct visit
                     ,sum(visit_status = "Scheduled visit") as count
      from id_visit_list
      group by visit
   ;
quit;

Вы можете заполнить массив во время цикла по группе, а затем выполнить любой алгоритм, который вы хотите оттуда. Вопрос, по-видимому, ищет посещения в 24, 18, 12 и 6 месяцах и перестает искать, когда произошло посещение (представляющих наибольший интерес) людей.

Пример:

Предположим, visit - числовая переменная. Значение visit может использоваться как индекс массива. Это известно как прямая адресация.

Рассмотрим два массива:

• months - это массив, роль которого заключается в хранении статического списка интересующих месяцев.
• visits - это массив с прямым адресом, который отслеживает, какие посещения имели место для id

Каждая группа id обрабатывается с использованием метода DOW, в котором оператор SET находится внутри явного цикла DO.

Таблица периодичности необходимых месяцев (т. Е. Количество) поддерживается в объекте hash.

Данные:

Data have;
Input id$ visit enrdate : mmddyy10. Vsdate : mmddyy10. ;
Format enrdate mmddyy10. Vsdate mmddyy10. visit z2.; 
Cards;
ABC01 00 1/2/2020 1/2/2020
ABC02 00 5/16/2020 5/16/2020
ABC02 06 5/16/2019 11/12/2019
CDC01 00 8/20/2019 8/20/2019
CDC01 06 8/20/2019 2/16/2020
EFG01 00 5/20/2020 5/20/2020
EFG02 00 12/2/2018 12/2/2018
EFG02 02 12/2/2018 1/31/2019
EFG02 06 12/2/2018 5/31/2019
EFG02 12 12/2/2018 12/2/2019
EFG03 00 3/3/2019 3/3/2019
EFG03 12 3/3/2019 3/2/2020
GFF04 00 6/2/2019 6/2/2019
GFF04 06 6/2/2019     .
;

Код:

data _null_;
  array months[1:4] _temporary_  (6,12,18,24);  * visit months of interest;
  array visits[0:24] _temporary_; * array for direct addressed have visit visits for by group.;

  if _n_ = 1 then do;
    declare hash counts (ordered: 'A');
    counts.defineKey('month');
    counts.defineData('month', 'count');
    counts.defineDone();
  end;

  * track visits that occurred;
  do _n_ = 1 by 1 until (last.id);
    set have end=done;
    by id;

    if visit <= hbound(visits) then do;
      visits(visit) = 1;
      flagged_count = sum(flagged_count,1);
    end;
  end;

  * presume enroll date is the same for all rows in the group;
  * at the end of the explicit loop `enrdate` will be available;

  * go from high to low months counting the needed months;

  do _n_ = hbound(months) to lbound(months) by -1;
    month = months(_n_);
  
    if missing(visits(month)) then do;
      * check if needed visit is in date span of interest;

      * compute the expected visit date;
      vsdate = intnx('month', enrdate, month, 'SAMEDAY');

      * if needed visit date is AFTER a cut off date perhaps an earlier one is before;
      if vsdate > '19AUG2021'D then CONTINUE;

      * if needed visit date is from a 'foggy' enrollment date then skip the id;
      if vsdate < '01JAN2020'D and missing(flagged_count) then LEAVE;
      
      * update counts;
      if counts.find() ne 0 then count = 1; else count + 1;
      counts.replace();
    end;
    else
      leave;  /* ignore all non-visits prior to a flagged visit */
  end;

  call missing(of visits[*]);

  if done then do;
    counts.output(dataset: 'want(label="Counts for needed visits")');
  end;

  keep id need;
run;

Вывод