Почему мое правило пролога застревает в бесконечной рекурсии

Когда вы вызываете что-то вроде travel(metz, To), последнее предложение travel/2 вызовет travel(metz, Z) с новой переменной Z, которая затем может вызвать travel(metz, Z2) с новой переменной Z2 и так далее.

Эта проблема называется левой рекурсией: у вас есть рекурсивный вызов, который эквивалентен исходной цели на всем пути слева (т. е. в начале) предложения. Решение состоит в том, чтобы добиться некоторого прогресса перед рекурсивным вызовом. В этом случае вы можете пройти один прыжок до рекурсии:

step(X, Y) :-
    byCar(X, Y).
step(X, Y) :-
    byTrain(X, Y).
step(X, Y) :-
    byPlane(X, Y).

travel(X, Y) :-
    step(X, Y).
travel(X, Z) :-
    step(X, Y),
    travel(Y, Z).

Теперь это заканчивается:

?- travel(metz, To).
To = frankfurt ;
To = paris ;
To = bangkok ;
To = singapore ;
To = auckland ;
To = hamilton ;
To = raglan ;
To = auckland ;
To = hamilton ;
To = raglan ;
To = losAngeles ;
To = auckland ;
To = hamilton ;
To = raglan ;
false.

Как указано в комментарии false, вы можете использовать общий предикат для фиксации такого закрытия: Определение рефлексивного транзитивного замыкания. В качестве альтернативы, некоторые системы Prolog предоставляют функцию, называемую таблицами, которую вы можете использовать, чтобы избежать проблем такого рода: https://www.swi-prolog.org/pldoc/man?section=tabling-non-termination