TPaintBox вращает изображение с помощью SetWorldTransform

Я загружаю изображение в TPaintBox, затем пытаюсь повернуть его с помощью SetWorldTransform, как предложено в этом ответе:

Изображение нормально загружается через TPaintBox.Invalidate -> TPaintBox.OnPaint.
Но когда я нажимаю тестовую кнопку BtnRotateWorldTransform, я вижу, что изображение мерцает, но не вращается.

procedure TFrmRotateImage.FormCreate(Sender: TObject);
begin
  FWICImage := TWICImage.Create; 
end;

procedure TFrmRotateImage.BtnLoadPaintBoxClick(Sender: TObject);
begin
   if DlgOpen.Execute then  // PNG or JPG file
   begin
      try
         FWICImage.LoadFromFile(DlgOpen.FileName);
         FBoxLoaded := true;
         PaintBox.Invalidate;
      finally
      end;
   end;
end;

procedure TFrmRotateImage.PaintBoxPaint(Sender: TObject);  // OnPaint handler
begin
   if not FBoxLoaded then Exit;
   PaintBox.Canvas.Draw(0,0,FWICImage);
end;

procedure TFrmRotateImage.BtnRotateWorldTransformClick(Sender: TObject);  // Test button
var
   lRect: TRect;
begin
   lRect.Top    := PaintBox.Top;
   lRect.Left   := PaintBox.Left;
   lRect.Width  := PaintBox.Width;
   lRect.Height := PaintBox.Height;
   StretchDrawRotated(PaintBox.Canvas,lRect,90,lRect.CenterPoint,FWICImage);
   PaintBox.Invalidate;
end;

с участием

procedure XForm_SetRotation(out AXForm: TXForm; AAngle: Extended; ACenter: TPoint);
var
  SinA, CosA: Extended;
begin
  SinCos(AAngle, SinA, CosA);
  AXForm.eM11 := CosA;
  AXForm.eM12 := SinA;
  AXForm.eM21 := -SinA;
  AXForm.eM22 := CosA;
  AXForm.eDx := (ACenter.X - (CosA * ACenter.X)) + ((SinA * ACenter.Y));
  AXForm.eDy := (ACenter.Y - (SinA * ACenter.X)) - ((CosA * ACenter.Y));
end;

procedure StretchDrawRotated(ACanvas: TCanvas; const ARect: TRect; AAngle: Extended; ACenter: TPoint; AGraphic: TGraphic);
var
  XForm, XFormOld: TXForm;
  GMode: Integer;
begin
  GMode := SetGraphicsMode(ACanvas.Handle, GM_ADVANCED);
  try
    if GetWorldTransform(ACanvas.Handle, XFormOld) then
      try
        XForm_SetRotation(XForm, AAngle, ACenter);
        SetWorldTransform(ACanvas.Handle, XForm);
        ACanvas.StretchDraw(ARect, AGraphic);
      finally
        SetWorldTransform(ACanvas.Handle, XFormOld);
      end;
  finally
    SetGraphicsMode(ACanvas.Handle, GMode);
  end;
end;

Что я забыл?


image rotation delphi vcl delphi-10.4-sydney
person Jan Doggen    schedule 03.09.2020    source источник
comment
Я бы позвонил StretchDrawRotated() внутри OnPaint().   -  person Olivier    schedule 03.09.2020
comment
Удалите PaintBox.Invalidate из обработчика кнопки, и вы увидите трансформацию. Конечно, это неправильное решение, но оно демонстрирует, что проблема заключается в непонимании того, как работает рисование.   -  person Sertac Akyuz    schedule 03.09.2020
comment
@SertacAkyuz Извините, не помогает   -  person Jan Doggen    schedule 03.09.2020
comment
@Olivier Пробовал это вместе с предложением Sertac скрыть Invalidate. Извини, нет.   -  person Jan Doggen    schedule 03.09.2020
comment
@ Ян, конечно, я имею в виду удалить недействительность в щелчке BtnRotateWorldTransform, а не в загрузчике. Я проверил, и это происходит, как я прокомментировал.   -  person Sertac Akyuz    schedule 03.09.2020
comment
@SertacAkyuz Да, тот   -  person Jan Doggen    schedule 03.09.2020
comment
Предлагаю перезапустить проект только из информации на этой странице - что я и сделал. Вы должны увидеть преобразованное изображение поверх исходного. Оттуда правильное решение довольно просто.   -  person Sertac Akyuz    schedule 03.09.2020
comment
Вы можете использовать Canvas2D для рисования изображения с любым преобразованием (поворот, масштабирование, перемещение, наклон, зеркальное отображение и другие). Можно комбинировать несколько трансформаций. Я написал две статьи francois-piette.blogspot. com/2020/08/ и Франсуа -piette.blogspot.com/2020/08/. Последний использует GDI+ для загрузки изображения, и если вы предпочитаете, вы можете заменить GDI+ на TWICImage.   -  person fpiette    schedule 04.09.2020

Ответы (1)


arrow_upward
2
arrow_downward

Я написал полный пример. В этом примере я показываю, как вращать, перемещать, масштабировать изображение и комбинировать эти преобразования.

Для этой цели я написал 3 функции, чтобы легко подготовить вращение, масштабирование и перемещение.

В обработчике событий PaintBox1Paint я беру фиксированные значения для поворота, масштабирования и перемещения. Конечно, в обычном приложении это происходит откуда-то еще (например, из пользовательского интерфейса). Вычисление преобразования должно быть вне процедуры PaintBox1Paint и выполняться каждый раз при изменении параметров. Затем следует вызвать Invalidate, чтобы он был перерисован с новым вычисленным преобразованием.

procedure TForm4.FormCreate(Sender: TObject);
begin
    FWICImage := TWICImage.Create;
end;

procedure TForm4.FormDestroy(Sender: TObject);
begin
    FreeAndNil(FWICImage);
end;

procedure TForm4.LoadImageButtonClick(Sender: TObject);
begin
    FWICImage.LoadFromFile('C:\Users\fpiette\Pictures\Delphi25 ICS.jpg');
    FBoxLoaded := TRUE;
    PaintBox1.Invalidate;
end;

function XForm_SetRotation(
    AAngle     : Single;
    ACenter    : TPoint) : TXForm;
var
    SinA, CosA: Extended;
begin
    SinCos(AAngle, SinA, CosA);
    Result.eM11 := CosA;
    Result.eM12 := SinA;
    Result.eM21 := -SinA;
    Result.eM22 := CosA;
    Result.eDx := (ACenter.X - (CosA * ACenter.X)) + ((SinA * ACenter.Y));
    Result.eDy := (ACenter.Y - (SinA * ACenter.X)) - ((CosA * ACenter.Y));
end;

function XForm_SetScale(
    const AZoomX : Single;
    const AZoomY : Single;
    const center: TPoint) : TXForm;
begin
    Result.eM11 := AZoomX;
    Result.eM12 := 0.0;
    Result.eM21 := 0.0;
    Result.eM22 := AZoomY;
    Result.eDx  := center.x - AZoomX * center.x;
    Result.eDy  := center.y - AZoomY * center.y;
end;

function XForm_SetTranslate(
    const ADistX : Integer;
    const ADistY : Integer) : TXForm;
begin
    Result.eM11 := 1.0;
    Result.eM12 := 0.0;
    Result.eM21 := 0.0;
    Result.eM22 := 1.0;
    Result.eDx  := ADistX;
    Result.eDy  := ADistY;
end;

procedure TForm4.PaintBox1Paint(Sender: TObject);
var
    XFormScale  : TXForm;
    XFormRot    : TXForm;
    XFormXLat   : TXForm;
    XForm       : TXForm;
    XFormOld    : TXForm;
    GMode       : Integer;
    AZoomFactor : Single;
    AAngle      : Single;
    ADistX      : Integer;
    ADistY      : Integer;
    ACanvas     : TCanvas;
begin
    if not FBoxLoaded then
        Exit;

    AZoomFactor := 0.25;
    AAngle      := 30.0;
    ADistX      := 100;
    ADistY      := 200;
    ACanvas     := PaintBox1.Canvas;

    GMode := SetGraphicsMode(ACanvas.Handle, GM_ADVANCED);
    try
        if GetWorldTransform(ACanvas.Handle, XFormOld) then begin
            try
                XFormRot   := XForm_SetRotation(
                                  AAngle,
                                  Point(FWICImage.Width div 2,
                                        FWICImage.Height div 2));
                XFormScale := XForm_SetScale(
                                  AZoomFactor, AZoomFactor, Point(0, 0));
                XFormXLat  := XForm_SetTranslate(ADistX, ADistY);
                CombineTransform(XForm, XFormRot, XFormScale);
                CombineTransform(XForm, XForm,    XFormXLat);
                SetWorldTransform(ACanvas.Handle, XForm);
                ACanvas.Draw(0, 0, FWICImage);
            finally
                SetWorldTransform(ACanvas.Handle, XFormOld);
            end;
        end;
    finally
        SetGraphicsMode(ACanvas.Handle, GMode);
    end;
end;
person fpiette    schedule 04.09.2020
comment
Большое спасибо, Франсуа. Я считаю себя новичком в графическом программировании, с этим рабочим кодом я могу начать возиться, чтобы посмотреть, что все это делает. - person Jan Doggen; 07.09.2020