Есть ли в Perl разница между прямым псевдонимом glob и псевдонимом через тайник?

Возможно, это не та разница, которую вы искали, но между *main::foo и $main::{foo} есть две большие разницы; первый ищет глобус в тайнике во время компиляции, создавая его при необходимости, а второй ищет глобус в тайнике во время выполнения и не создает его.

Это может иметь значение для чего-либо еще в тайнике, и это, безусловно, может повлиять на то, получите ли вы предупреждение used only once.

Следующий скрипт:

#!/usr/bin/env perl

#mytest.pl

no warnings;


$bar = "this";
@bar = qw/ 1 2 3 4 5 /;
%bar = qw/ key value /;

open bar, '<', 'mytest.pl' or die $!;

sub bar {
    return "Sub defined as 'bar()'";
}
$main::{foo} = $main::{bar};

print "The scalar \$foo holds $foo\n";
print "The array \@foo holds @foo\n";
print "The hash \%foo holds ", %foo, "\n";
my $line = <foo>;
print "The filehandle 'foo' is reads ", $line;
print 'The function foo() replies "', foo(), "\"\n";

Выходы:

The scalar $foo holds this
The array @foo holds 1 2 3 4 5
The hash %foo holds keyvalue
The filehandle 'foo' is reads #!/usr/bin/env perl
The function foo() replies "Sub defined as 'bar()'"

Поэтому, если *main::foo = *main::bar; не делает то же самое, что $main::{foo} = $main::{bar};, я не знаю, как обнаружить практическую разницу. ;) Однако с точки зрения синтаксиса могут быть ситуации, когда проще использовать один метод, а не другой. ...всегда применяются обычные предупреждения о манипуляциях с таблицей символов.

Доступ к тайнику как $A::{foo} = $obj позволяет вам размещать что угодно в таблице символов, в то время как *A::foo = $obj помещает $obj в ожидаемый слот typeglob в соответствии с типом $obj.

Например:

  DB<1> $ST::{foo} = [1,2,3]

  DB<2> *ST::bar = [1,2,3]

  DB<3> x @ST::foo
Cannot convert a reference to ARRAY to typeglob at (eval 7)[/usr/local/perl/blead-debug/lib/5.15.0/perl5db.pl:646] line 2.
 at (eval 7)[/usr/local/perl/blead-debug/lib/5.15.0/perl5db.pl:646] line 2
    eval '($@, $!, $^E, $,, $/, $\\, $^W) = @saved;package main; $^D = $^D | $DB::db_stop;
  @ST::foo;

;' called at /usr/local/perl/blead-debug/lib/5.15.0/perl5db.pl line 646
    DB::eval called at /usr/local/perl/blead-debug/lib/5.15.0/perl5db.pl line 3442
    DB::DB called at -e line 1
  DB<4> x @ST::bar
0  1
1  2
2  3
  DB<5> x \%ST::
0  HASH(0x1d55810)
   'bar' => *ST::bar
   'foo' => ARRAY(0x1923e30)
      0  1
      1  2
      2  3

См. также "Скаляры против глобусов (*{} не должен возвращать FAKE globs)"

https://github.com/perl/perl5/issues/10625