Добавить более 25 элементов в поле раскрывающегося списка в MS Word VBA

Если вы не пытаетесь поддерживать действительно старые версии Word, я поддерживаю предложение Macropod по управлению контентом. Word для Mac 2011 был последней версией, которая их не поддерживала. Вот ваш код в версии управления контентом:

Sub Alang()
    Dim oCC As ContentControl
        
    For Each oCC In ActiveDocument.ContentControls
        If oCC.Title = "alang" Then
            With oCC.DropdownListEntries
                .Clear
                .Add "Afrikaans"
                'Other languages here
            End With
        End If
    Next oCC
End Sub

Вы не можете добавить более 25 элементов в раскрывающийся список полей формы в MS Word. Это конструктивное ограничение.

Вместо раскрывающегося списка полей формы вам следует рассмотреть возможность использования раскрывающегося списка элементов управления содержимым. Выпадающие списки управления контентом могут иметь сотни, если не тысячи, записей (хотя как вам удастся выбрать элемент из такого монстра, не стоит думать). Например:

Sub Demo()
Application.ScreenUpdating = False
Dim i As Long
Const StrList As String = "|Afrikaans|Albanian|Arabic|Assamese|Belarusian|Bengali|" & _
  "Bosnian|Bulgarian|Catalan|Cebuano|Chinese - Simplified|Chinese - Traditional|" & _
  "Creole - Haitian|Croatian|Czech|Dagbani|Danish|Dholuo|Dutch|English|Estonian|" & _
  "Ewe|Finnish|French|Gaelic - Irish|Gaelic - Welsh|Georgian|German|Greek|Gujarati|" & _
  "Hebrew|Hiligaynon|Hindi|Hungarian|Icelandic|Iloko/Ilocano|Indonesian|" & _
  "Italian|Itesot|Japadhola|Japanese|Kannada|Korean|Latvian|Lithuanian|" & _
  "Luganda|Macedonian|Malay|Malayalam|Marathi|Norwegian|Odia/Oriya|Pedi|" & _
  "Polish|Portuguese (Brazil)|Portuguese (Portugal)|Punjabi|Romanian|Russian|" & _
  "Serbian - Cyrillic|Serbian - Latin|Sesotho|Setswana|Sinhalese|Slovak|" & _
  "Slovenian|Spanish|Spanish (Universal)|Swahili|Swedish|Tagalog|Tamil|Telugu|" & _
  "Thai|Tsonga|Turkish|Twi|Ukrainian|Urdu|Uyghur|Venda|Vietnamese|Welsh|Xhosa|Zulu"
With ActiveDocument.SelectContentControlsByTitle("alang")
  For c = 1 To .Count
    With .Item(c)
      .SetPlaceholderText Text:="Choose a Language"
      With .DropdownListEntries
        .Clear
        For i = 1 To UBound(Split(StrList, "|"))
          .Add Split(StrList, "|")(i)
        Next
      End With
    End With
  Next
End With
Application.ScreenUpdating = True
End Sub

Конечно, использование раскрывающегося списка управления содержимым может потребовать совершенно другого подхода к другим аспектам того, что вы делаете; во-первых, поля формы и элементы управления содержимым не должны использоваться в одном и том же документе. Они не были предназначены для использования таким образом, и попытка сделать это является известным источником проблем.