Умножение путем сопоставления в yacc

Как указано в ответе на вопрос, который вы связали, трудно указать приоритет оператора сопоставления, потому что нет оператора для сдвига. (Как и в вашем коде, вы можете указать приоритет производственного expr: expr expr. Но с каким упреждающим токеном будет сравниваться это сокращение? Добавление каждого токена в FIRST(expr) к вашим объявлениям приоритета не очень масштабируемо и может привести к нежелательному приоритету резолюции.

Дополнительная проблема с решением приоритета заключается в поведении унарного оператора минус (проблема, не рассматриваемая в связанном вопросе), потому что, как написано, ваша грамматика позволяет анализировать a - b либо как вычитание, либо как сопоставленное умножение a и -b. (И обратите внимание, что - находится в FIRST(expr), что приводит к одному из возможных нежелательных разрешений, о которых я упоминал выше.)

Таким образом, лучшие решения, как рекомендуется в связанном вопросе, - это использовать грамматику с явным приоритетом, например следующую: (Здесь я использовал juxt в качестве имени нетерминала, а не expr_sequence):

%start  prgm
%token  NUM
%token  VAR

%left   '+' '-'
%left   '*' '/'
%right  '^'
%%
prgm:     // nothing
    | prgm '\n'
    | prgm expr '\n'
expr: juxt
    | '-' juxt
    | expr '+' expr
    | expr '-' expr
    | expr '*' expr
    | expr '/' expr
    | expr '^' expr
juxt: atom
    | juxt atom
atom: NUM
    | VAR
    | '(' expr ')'

Эта грамматика может быть не тем, что вам нужно:

• это довольно простое обращение с унарным минусом имеет несколько проблем. Я не думаю, что проблематично то, что он анализирует -xy в -(xy) вместо (-x)y, но это не идеально. Кроме того, он не позволяет --x (тоже, вероятно, не проблема, но не идеально). Наконец, он анализирует -x^y не как -(x^y), а как (-x)^y, что противоречит частой практике.
• Кроме того, он неправильно связывает сопоставление слишком сильно. Вы можете или не можете считать проблемой то, что a/xy анализируется как a/(xy), но вы, вероятно, будете возражать против того, чтобы 2x^7 анализировалось как (2x)^7.

Самый простой способ избежать этих проблем — использовать грамматику, в которой приоритет операций единообразно реализован с помощью однозначных правил грамматики.

Вот пример, который реализует стандартные правила приоритета (возведение в степень имеет приоритет над унарным минусом; сопоставление умножения имеет тот же приоритет, что и явное умножение). Стоит потратить несколько минут, чтобы внимательно посмотреть, какой нетерминал появляется в какой продукции, и подумать о том, как это коррелирует с желаемыми правилами приоритета.

%union {
    double  num;
    char    *var;
    ASTNode *node;
}
%token  <num>   NUM
%token  <var>   VAR
%type   <node>  expr mult neg expt atom

%%
prgm:     // nothing
    | prgm '\n'
    | prgm error '\n'
    | prgm expr '\n'
expr: mult
    | expr '+' mult
    | expr '-' mult
mult: neg
    | mult '*' neg
    | mult '/' neg
    | mult expt
neg : expt
    | '-' neg
expt: atom
    | atom '^' neg
atom: NUM
    | VAR
    | '(' expr ')'