Скрипт действий 2. Ключевые точки событий: findNearestCuePoint

Давно не трогал AS2. Я сделал базовый тест, и findNearestCuePoint сработал. Вы используете компонент FLVPlayback, верно? Вот что я пробовал:

videoPlayer.autoPlay = false;
onEnterFrame = function():Void{
    videoPlayer.seekPercent(_xmouse/Stage.width * 100);
    videoPlayer.play();
    trace(videoPlayer.findNearestCuePoint(videoPlayer.playheadTime).name);
}

Рекомендуемый способ — найти ближайшую ключевую точку в playheadUpdate обработчик, который срабатывает после того, как указатель воспроизведения изменяет свое значение. (например, 1. сказать, чтобы указатель воспроизведения переместился, 2. указатель воспроизведения фактически изменяет значение, 3. вызывается playheadUpdate)

Вот более простой подход:

onEnterFrame = function():Void{
    if(videoPlayer.metadata) trace(videoPlayer.findNearestCuePoint(_xmouse/Stage.width * videoPlayer.metadata.duration).name);
}

В моем тесте я добавил 4 ключевые точки. Пробовал их все: actionscript/event/navigation. Странно было то, что когда я пытался получить доступ к свойству cuePoints через videoPlayer или через videoPlayer.metadata, я получил массив из 8 неопределенных объектов, и длина массива была 4, когда я его трассировал. Не знаю, в чем проблема, возможно, кодировка/кодек и совместимость с as2, не уверен.

В любом случае... пока у вас есть массив cuePoints, вы можете вручную найти ближайший, перебирая их все и получая наименьшую абсолютную разницу между временем каждой ключевой точки и текущим временем:

function getClosestCuePoint(cuePoints:Array,time:Number):Object{
    var numCuePoints:Number = cuePoints.length;
    var minDist:Number = 100000000,result:Object;
    for(var i:Number = 0 ; i < numCuePoints ; i++){
        if(Math.abs(cuePoints[i].time - time) < minDist){
            minDist = Math.abs(cuePoints[i].time - time);
            result = cuePoints[i];
        }
    }
    return result;
}

Вот пример макета: давайте представим, что некоторые поля на экране являются контрольными точками, а позиция _xmouse будет временем воспроизведения. Попробуйте это в новом документе:

//fake cue points
var numCuePoints:Number = 5;
var cuePoints = [];
for(var i:Number = 0 ; i < numCuePoints ; i++) cuePoints[i] = {name:'narration ' + (i+1),time: 10 + (80 + Math.random() * 20) * i}
//visual hint - separated from the cue points
for(var i:Number = 0 ; i < numCuePoints ; i++) drawBox(this,0x009900,10,15,cuePoints[i].time,Stage.width * .5);
var playhead:TextField = drawText(this,'playhead');

//playhead update
onEnterFrame = function():Void{
    playhead._x = _xmouse;
    playhead.setTextFormat(new TextFormat('Verdana',11));
    playhead.text = 'time: ' + _xmouse+' / cue ' + getClosestCuePoint(cuePoints,_xmouse).name;
}
//find the shortest marker within the shortest distance from the current value
function getClosestCuePoint(cuePoints:Array,time:Number):Object{
    var numCuePoints:Number = cuePoints.length;
    var minDist:Number = 100000000,result:Object;
    for(var i:Number = 0 ; i < numCuePoints ; i++){
        if(Math.abs(cuePoints[i].time - time) < minDist){
            minDist = Math.abs(cuePoints[i].time - time);
            result = cuePoints[i];
        }
    }
    return result;
}
//utils
function drawBox(target:MovieClip,color:Number,width:Number,height:Number,x:Number,y:Number):Void{
    target.lineStyle(3,color);
    target.moveTo(x,y);
    target.lineTo(x+width,y);
    target.lineTo(x+width,y+height);
    target.lineTo(x,y+height);
    target.lineTo(x,y);
}
function drawText(target:MovieClip,name:String):TextField{
    var result:TextField = target.createTextField(name,target.getNextHighestDepth(),0,Stage.width * .5-20,100,20);
    result.autoSize = 'left';
    result.border = true;
    result.selectable = false;
    return result;
}

ХТН

Джордж,

Я считаю, что обнаружил проблему, и я думаю, что это было то, что вы описали в своем предыдущем посте, но я случайно не упомянул об этом.

В F4V, с которым я работал, ключевые точки были встроены с помощью Adobe Media Encoder... и в этом была вся проблема.

Я вернулся и экспортировал контрольные точки в XML, затем удалил их из F4V и перекодировал без них. Затем я отредактировал XML, заменив все ключевые точки событий на сценарии действий, и импортировал их в файл FLA с помощью диалогового окна свойств компонента FLV.

Престо, как ни удивительно, у меня не было проблем с поиском ключевых точек, их отслеживанием и использованием для любых целей.

Так что в будущем мне просто нужно не забыть настроить ключевые точки в диалоговом окне «Свойства» и установить для них сценарий действия, и я должен быть золотым. До сих пор он безупречно работал со всеми файлами F4V с момента внесения изменений.

Большое спасибо за подробный ответ и за продолжение!