Блок smalltalk — могу ли я явно установить возвращаемое значение и остановить выполнение блока?

Внутри блока нет ничего похожего на защитное предложение — blah ifTrue: [^ foo], потому что ^ — это нелокальный возврат, возвращаемый из метода, вызывающего блок, а не из самого блока.

Большие блоки — как и большие объекты — должны быть реорганизованы в более мелкие, более понятные/удобные части, но иногда это не всегда возможно. Я имею в виду этот ответ, чтобы предложить варианты, которые можно попробовать, когда вы не можете действительно упростить обычными способами.

Если ваш блок действительно настолько сложен, и вы не можете сделать его проще (например, его разбиение слишком делокализует информацию), то, возможно, вы можете использовать явное возвращаемое значение. В частности, если ваш блок не возвращает nil, вы можете сделать что-то вроде

[:one :two | | result |
    result := (one isNil and: [two isNil]) ifTrue: [false].
    result ifNil: ["do one thing, possibly setting result"].
    result]

Если ваш блок может возвращать nil, вам понадобится другое сигнальное значение:

[:one :two | | result marker |
    result := marker := Object new.
    (result == marker) ifTrue: ["do one thing, possibly setting result"].
    result]

Наконец - и я не решаюсь предложить это - вы могли бы сделать это:

[1 + 2.
thisContext return: 5.
3 + 4] value

который возвращает 5.

(Проверка того, как это взаимодействует с ^ и встроенными селекторами, такими как #ifTrue:ifFalse:, оставлена ​​читателю в качестве упражнения.)

Похоже, ваш код пытается обрабатывать ноль как значение бесконечность при сравнении один и два. Следующий код может быть более читаемым в зависимости от контекста:

a := [:one :two |
    | x y |
    x := one ifNil: [Float infinity].
    y := two ifNil: [Float infinity].
    (x = y) ifTrue: [nil] ifFalse: [x > y]]

Полезная функция #ifTrue:ifFalse:, #ifNil:ifNotNil: и подобных методов тестирования заключается в том, что они возвращают значение оцениваемого блока. например (4 > 1) ifTrue: ['greater'] ifFalse: ['not-greater'] оценивается как 'больше'. Эта функция часто позволяет вернуть значение из вложенного блока в хвостовой позиции.

Когда код внутри блока становится слишком сложным, я предлагаю реорганизовать его в метод. Но посмотрите ответ Фрэнка для обходных путей.

Изменить:

Как указано в комментариях, приведенный выше код предполагает числа. Я также придумал кое-что, что работает с другими сопоставимыми объектами:

a:=
[ :one :two |
  true caseOf: {
    [one = two]->[nil].
    [one isNil]->[true].
    [two isNil]->[false]
  } otherwise: [one>two]]

Эта конструкция #caseOf: используется редко, но она определенно лучше, чем thisContext return:

Вы хотите реализовать прерывание, продолжение, выход... Обычный способ управления потоком в Smalltalk — это блоки. Таким образом, одно забавное решение состоит в том, чтобы использовать вспомогательный метод с возвращаемым значением Block, чтобы прервать поток, как описано здесь .

Object>>exitThru: aBlock
    ^aBlock value: [:result | ^result]

Теперь давайте посмотрим, как его использовать:

| aBlock |
aBlock :=   [ :one :two |
    self exitThru: [:exit |
        one isNil ifTrue: [ two isNil ifTrue: [exit value: nil ] ifFalse: [ exit value: true ] ].
        two isNil ifTrue: [ exit value: false ].
        one > two ifTrue: [ exit value: true ].
        one < two ifTrue: [ exit value: false ].
        exit value: nil] ].

#(('abc' nil) (nil nil) (nil 'def') ('y' 'abc') ('y' 'y') ('y' 'z'))
    collect:
        [:pair |
        aBlock value: pair first value: pair last ]
-> #(false nil true true nil false)

EDIT моя первая версия была излишне сложной, не могу вспомнить, что привело меня к дополнительной косвенности:

| aBlock |
aBlock :=  [:wrapOne :wrapTwo |
    self exitThru: [:exit |
        [ :one :two |
        one isNil ifTrue: [ two isNil ifTrue: [exit value: nil ] ifFalse: [ exit value: true ] ].
        two isNil ifTrue: [ exit value: false ].
        one > two ifTrue: [ exit value: true ].
        one < two ifTrue: [ exit value: false ].
        exit value: nil ]
            value: wrapOne value: wrapTwo ] ].

Что ж, скорее смешно, чем полезно, надеюсь, вы найдете более простой и выразительный способ кодирования.