Delphi 7 - обработка событий MouseWheel для встроенных фреймов в формах?

Привет, у меня есть форма с несколькими рамками внутри.

Для некоторых кадров я хочу прокрутить содержимое (или, по крайней мере, обработать событие колеса мыши).

Я пробовал следующее:

Простое назначение обработчика события OnMouseWheel для каждого кадра

Переопределение события MouseWheel для родительской формы:

procedure TFmReview.MouseWheelHandler(var Message: TMessage);
var   Control: TControl;
begin
    Control := ControlAtPos(ScreenToClient(SmallPointToPoint(TWMMouseWheel(Message).Pos)), False, True);
    if Assigned(Control) and (Control <> ActiveControl) then
    begin
         ShowMessage(Control.Name);
         Message.Result := Control.Perform(CM_MOUSEWHEEL, Message.WParam, Message.LParam);
         if Message.Result = 0 then
            Control.DefaultHandler(Message);
     end else inherited MouseWheelHandler(Message);
end;

К сожалению, оба варианта не работают.

  • В случае 1 событие никогда не запускается, однако запускается обработчик колеса мыши родительской формы.
  • В случае 2 элемент управления, который получает фокус, - это панель, содержащая фрейм, в который я хочу отправить событие колеса мыши.

Итак, проще говоря, как я могу направить событие колеса мыши на самый верхний элемент управления, над которым находится курсор мыши (независимо от того, в каком фрейме / родительском элементе / форме и т. Д. Находится курсор)?


focus mousewheel delphi tframe tform
person Simon    schedule 10.11.2011    source источник
comment
Взгляните на [эти ответы SO] [1], они, вероятно, помогут. [1]: stackoverflow.com/questions/2472743/   -  person Brian Frost    schedule 10.11.2011
comment
возможный дубликат Как направить колесо мыши на управление под курсором, а не в фокусе?   -  person Kromster    schedule 24.02.2014

Ответы (1)


arrow_upward
1
arrow_downward

Чтобы отложить обработку колесика мыши до TWinControl, над которым в данный момент находится курсор мыши, переопределите в своем основном фрейме метод MouseWheelHandler, используя такой код, как это:

type
  TMainForm = class(TForm)
  private
    procedure MouseWheelHandler(var AMessage: TMessage); override;
  public
    { Public declarations }
  end;

implementation

procedure TMainForm.MouseWheelHandler(var AMessage: TMessage);
var
  Control: TWinControl;
begin
  Control := FindVCLWindow(SmallPointToPoint(TWMMouseWheel(AMessage).Pos));
  if Assigned(Control) then
  begin
    AMessage.Result := Control.Perform(CM_MOUSEWHEEL, AMessage.WParam,
      AMessage.LParam);
    if AMessage.Result = 0 then
      Control.DefaultHandler(AMessage);
  end
  else
    inherited MouseWheelHandler(AMessage);
end;
person TLama    schedule 10.09.2012
comment
По какой-то причине этот код создает StackOverflow, когда я прокручиваю над TMainForm. - person Kromster; 21.02.2014