Есть ли способ заменить if-elsif-else в Perl чем-то лучшим?

Несколько человек упомянули диспетчерскую таблицу. Есть две вещи, и иногда приятно их разделить. Есть список возможных вещей, которые могут произойти, и то, что заставляет их происходить. Если вы соедините их, вы застряли со своим решением. Если вы сохраните их отдельно, у вас будет больше гибкости позже.

Таблица диспетчеризации определяет поведение в виде данных, а не структуры программы. Вот два разных способа сделать это. В вашем примере у вас есть целые числа, и что-то в этом роде может использовать массив для хранения вещей. В примере с хэшем используется та же идея, но поведение выглядит несколько иначе.

Также обратите внимание, что я не учитываю print. Когда у вас есть повторяющийся код, попробуйте переместить повторяющийся материал на уровень выше.

use v5.10;

foreach my $factor ( map { int rand 5 } 0 .. 9 ) {
    say get_age_array( $factor );
    }

my @animals = qw( cat dog bird frog );
foreach my $factor ( map { $animals[ rand @animals ] } 0 .. 9 ) {
    say get_age_hash( $factor );
    }

sub get_age_array {
    my $factor = shift;

    state $dispatch = [
        sub { 'Nothing!' }, # index 0
        sub { "Calling 1" },
        sub { 1 + 1 },
        sub { "Called 3" },
        sub { time },
        ];

    return unless int $factor <= $#$dispatch;

    $dispatch->[$factor]->();   
    }


sub get_age_hash {
    my $factor = shift;

    state $dispatch = {
        'cat'  => sub { "Called cat" },
        'dog'  => sub { "Calling 1"  },
        'bird' => sub { "Calling 2, with extra" },
        };

    return unless exists $dispatch->{$factor};

    $dispatch->{$factor}->();   
    }

Обновление: обязательно прочитайте комментарий Брайана ниже; в основном, лучше использовать for вместо given из-за различных проблем, которые он комментирует в своей ссылке. Я обновил свой совет, чтобы включить его улучшения, которые он описывает в Используйте for() вместо заданного():

Если вы используете perl 5.10 или новее, given/when — это волшебная пара, которую вы ищете, но вместо этого вам действительно следует использовать for/when. Вот пример:

use strict;
use warnings;
use feature qw(switch say);

print 'Enter your grade: ';
chomp( my $grade = <> );

for ($grade) {
    when ('A') { say 'Well done!'       }
    when ('B') { say 'Try harder!'      }
    when ('C') { say 'You need help!!!' }
    default { say 'You are just making it up!' }
}

просто короче:

sub get_age1 {
    my $age = shift;
    $age == 1 ? print "do something" :
    $age == 2 ? print "do somthing2" :
    $age == 3 ? print "do somthing3" :
    $age == 4 ? print "do somthing4" :
                print "error"
}

это имеет больше смысла, если условие лучше всего выразить в виде регулярного выражения:

sub get_age2 {    
    for (shift) { 
        if    (/^ 1 $/x) {print "do something"}
        elsif (/^ 2 $/x) {print "do somthing2"}
        elsif (/^ 3 $/x) {print "do somthing3"}
        elsif (/^ 4 $/x) {print "do somthing4"}
        else             {print "error"       }
    }
}

вот несколько таблиц отправки:

простой (с ошибкой):

{
    my %age = ( # defined at runtime
        1 => sub {print "do something"},
        2 => sub {print "do somthing2"},
        3 => sub {print "do somthing3"},
        4 => sub {print "do somthing4"},
    );
    # unsafe to call get_age3() before sub definition
    sub get_age3 {
        ($age{$_[0]} or sub {print "error"})->()
    }
}

лучше:

{
    my %age;
    BEGIN {
        %age = ( # defined at compile time
            1 => sub {print "do something"},
            2 => sub {print "do somthing2"},
            3 => sub {print "do somthing3"},
            4 => sub {print "do somthing4"},
        )
    }
    # safe to call get_age4() before sub definition
    sub get_age4 {
        ($age{$_[0]} or sub {print "error"})->()
    }
}

другой способ написать это:

BEGIN {
    my %age = ( # defined at compile time
        1 => sub {print "do something"},
        2 => sub {print "do somthing2"},
        3 => sub {print "do somthing3"},
        4 => sub {print "do somthing4"},
    );
    # safe to call get_age5() before sub definition
    sub get_age5 {
        ($age{$_[0]} or sub {print "error"})->()
    }
}

другой хороший способ написать это:

{
    my $age;
    # safe to call get_age6() before sub definition
    sub get_age6 {
        $age ||= { # defined once when first called
           1 => sub {print "do something"},
           2 => sub {print "do somthing2"},
           3 => sub {print "do somthing3"},
           4 => sub {print "do somthing4"},
        };
        ($$age{$_[0]} or sub {print "error"})->()
    }
}

Диспетчерские таблицы идеально подходят для этого типа шаблона проектирования. Я использовал эту идиому много раз. Что-то вроде этого:

sub get_age {
    my $facter = shift;
    my %lookup_map = (
        1 => sub {.....},
        2 => sub {.....},
        3 => \&some_other_sub,
        default => \&some_default_sub,
    );
    my $code_ref = $lookup_map{$facter} || $lookup_map{default};
    my $return_value = $code_ref->();
    return $return_value;
}

Это работает, когда аргумент, который вы используете для определения того, какой случай будет выполнен, будет существовать как ключ в вашей хеш-таблице. Если возможно, что это не будет точное совпадение, вам может потребоваться использовать регулярные выражения или какой-либо другой способ сопоставить ваш ввод с тем, какой фрагмент кода выполнять. Вы можете использовать регулярные выражения в качестве хэш-ключей следующим образом:

my %patterns = (
    qr{^/this/one}i => sub {....},
    qr{^/that/one}is => sub {....},
    qr{some-other-match/\d+}i => \&some_other_match,
)
my $code_ref;
for my $regex (keys %patterns) {
    if ($facter =~ $regex) {
        $code_ref = $patterns{$regex};
        last;
    }
}
$code_ref ||= \&default_code_ref;
$code_ref->();

См. примеры/ссылки/dispatch_table.pl

https://code-maven.com/slides/perl/dispatch-table

#!/usr/bin/perl
use strict;
use warnings;

# Use subroutine references in a hash to define what to do for each case

my %dispatch_table = (
    '+' => \&add,
    '*' => \&multiply,
    '3' => \&do_something_3,
    '4' => \&do_something_4,
);

foreach my $operation ('+', 'blabla', 'foobar', '*'){
    $dispatch_table{$operation}->(
        var1 => 5,
        var2 => 7,
        var3 => 9,                       
    ) if ( exists $dispatch_table{$operation} );
}

sub add {
    my %args = (@_);
    my $var1 = $args{var1}; 
    my $var2 = $args{var2};

    my $sum = $var1 + $var2;
    print "sum = $sum \n";
    return;
}

sub multiply {
    my %args = (@_);
    my $var1 = $args{var1}; 
    my $var3 = $args{var3};

    my $mult = $var1 * $var3;
    print "mult = $mult \n";
    return;
}

Вывод:

sum = 12 
mult = 45 

Это может быть место для чего-то вроде диспетчерского стола. Я не делал этого сам, но эта страница может быть отправной точкой: http://www.perlmonks.org/?node_id=456530

используйте Switch;

Прочитайте таблицы отправки в Perl более высокого порядка.