Repa Как сделать экземпляр Read?

Такой экземпляр будет сиротским экземпляром, чего обычно следует избегать. Однако написать его довольно просто:

{-# LANGUAGE TypeOperators #-}

import Data.Array.Repa (Array, Shape, Elt, Z(..), (:.)(..))
import qualified Data.Array.Repa as R

instance Read Z where
  readsPrec _ r = do
    ("Z", s) <- lex r
    return (Z, s)

instance (Read tail, Read head) => Read (tail :. head) where
  readsPrec d =
    readParen (d > prec) $ \r -> do
      (tl, s) <- readsPrec (prec + 1) r
      (":.", t) <- lex s
      (hd, u) <- readsPrec (prec + 1) t
      return (tl :. hd, u)
    where prec = 3

instance (Shape sh, Read sh, Elt a, Read a) => Read (Array sh a) where
  readsPrec d =
    readParen (d > app) $ \r -> do
      ("Array", s) <- lex r
      (sh, t) <- readsPrec (app + 1) s
      (xs, u) <- readsPrec (app + 1) t
      return (R.fromList sh xs, u)
    where app = 10

Если вы используете расширение StandaloneDeriving, первые два экземпляра можно упростить:

deriving instance Read Z
deriving instance (Read tail, Read head) => Read (tail :. head)

Эти экземпляры, вероятно, должны быть в самой repa; Я просто основывал их на экземпляре примера, приведенном в Text.Show и вывод repa show. Я предлагаю сделать запрос функции на системе отслеживания ошибок repa и поместить эти экземпляры в модуль вашей программы на данный момент (если вы не хотите избежать экземпляры-сироты полностью, и в этом случае вам придется решать проблему совсем другим способом).

Тем не менее, вам, вероятно, следует подумать о простом преобразовании ваших данных в список (с toList) и его использовании; он избегает экземпляра-сироты и не должен иметь никаких недостатков. Вы также можете рассмотреть возможность использования «настоящей» библиотеки сериализации, такой как cereal, если вас больше интересует обработка данных с помощью код, чем то, что он должен быть удобочитаемым; Read обычно считается довольно ограниченным применением.