отображение поля даты в значении формы поля даты

Чтобы ссылаться на имена динамических столбцов, вы можете использовать нотацию массива. Но, как я уже упоминал, вы должны указать номер строки.

 #queryName["columnName"][rowNumber]#

Если вы знаете, что запрос содержит только одну (1) запись, вы можете использовать свойство «recordCount» объекта запроса в качестве номера строки. В качестве альтернативы вы можете жестко закодировать номер строки «1». (Лично мне не нравится жесткое кодирование). Но любой из них должен работать.

<!--- pick ONE option ---> 
<cfloop from="1" to="#form.days#" index="i">
   <!--- syntax option 1 ---> 
   <cfinput type="datefield" name="ses#i#Date" value="#DateFormat(qGetUWHeader['ses#i#Date'][qGetUWHeader.recordCount], 'yyyy-mm-dd')#" />
   <!--- syntax option 2 ---> 
   <cfinput type="datefield" name="ses#i#Date" value="#DateFormat(qGetUWHeader['ses'& i &'Date'][qGetUWHeader.recordCount],'yyyy-mm-dd')#" />
   <!--- syntax option 3 ---> 
   <cfinput type="datefield" name="ses#i#Date" value="#DateFormat(qGetUWHeader['ses#i#Date'][1], 'yyyy-mm-dd')#" />
</cfloop>

Однако, если вы просматриваете несколько записей в запросе qGetUWHeader, вы можете использовать свойство "currentRow" объекта запроса в качестве номера строки. Но, исходя из соглашения об именах полей, я предполагаю, что запрос содержит только одну (1) запись.

РЕДАКТИРОВАТЬ: я забыл о начальных нулях. Вы можете применить простое условие if и вызывать DateFormat () только в том случае, если значение запроса является допустимой датой.

<cfloop from="1" to="#form.days#" index="i">
    <cfset dateValue = qGetUWHeader["ses#i#Date"][qGetUWHeader.recordCount]>
    <!--- if this is a valid date, format the value --->
    <cfif IsDate(dateValue)>
      <cfset dateValue = dateFormat(dateValue, "yyyy-mm-dd")>
    </cfif> 
    <cfinput type="datefield" name="ses#i#Date" value="#dateValue#" /><hr>
</cfloop>

Другой вариант - отформатировать даты в вашем SQL. Тогда вам не нужно будет использовать функцию CF DateFormat (). Просто имейте в виду, что новым результатом будет строка, не объект datetime.

SELECT DATE_FORMAT(ses1Date, '%Y-%m-%d') AS ses1Date, ....

Где определяется "qGetUWHeader"?

Когда форма отправляется, все значения будут отправлены в область формы. Следовательно, чтобы отобразить значение из обратной передачи, вы должны ссылаться на область формы, если вы не копируете значение в qGetUWHeader. Несмотря на то, что правильная дата из формы сохраняется в области формы, вы показываете значение по умолчанию из qGetUWHeader при обратной отправке, если вы не делаете там что-то, о чем я не знаю. Затем, когда вы в следующий раз опубликуете форму, значение по умолчанию переопределит ранее введенное значение.

<!--- In order to reference FORM values, you must CFPARAM them first to define the default value. --->
<cfparam name="form.days" default="10">
<cfloop from="1" to="#form.days#" index="i">
    <cfparam name="form['ses#i#Date']" default="">
</cfloop>

<!--- Display the Form --->
<cfform action="#cgi.SCRIPT_NAME#" method="post">
    <cfloop from="1" to="#form.days#" index="i">
      <cfset thisFieldName = "ses" & i & "Date">
      <cfset thisFieldValue = form["ses#i#Date"]>
      <cfoutput>#thisFieldName#</cfoutput> <!--- For Debugging --->
      <cfinput type="datefield" name="#thisFieldName#" value="#thisFieldValue#" /><br /><br />
    </cfloop>
    <input type="submit" name="submit" value="submit" />
</cfform>

<!--- Debug --->
<cfdump var="#form#">