Как настроить размер большого пальца TrackBar?

Казалось бы, это невозможно сделать с помощью стандартного элемента управления трекбаром. Действительно, я не вижу никакой трекбара стиль или панель управления сообщение по этому поводу. Есть только TBM_SETTHUMBLENGTH, к которому вы также можете получить доступ из TTrackBar.ThumbLength VCL, но это также влияет на высоту утопленного прямоугольника фона.

Конечно, вы всегда можете сделать свой собственный трекбар управление.

Или вы хотите только уменьшить затонувший прямоугольник? Затем просто установите ShowSelRange в False в инспекторе объектов. Но если темы включены, вы все равно не можете сделать большой палец больше примерно 24.

Если вы используете старую версию Delphi без TrackBar.ShowSelRange, вам необходимо вручную удалить стиль окна TBS_ENABLESELRANGE. Вы можете сделать это в любое время, используя SetWindowLong, или вы можете сделать это в CreateParams подкласса элемента управления трекбар. Самым простым способом может быть использование «класса промежуточного звена»:

type
  TTrackBar = class(ComCtrls.TTrackBar)
  protected
    procedure CreateParams(var Params: TCreateParams); override;
  end;

...   
implementation

{ TTrackBar }

procedure TTrackBar.CreateParams(var Params: TCreateParams);
begin
  inherited;
  Params.Style := Params.Style and not TBS_ENABLESELRANGE;
end;

Чтобы получить внешний вид на снимке экрана Notepad ++, вы также должны установить TickMarks на tmBoth и TickStyle на tsNone.

Однако это не отвечает на ваш вопрос, который касался увеличения большого пальца. Это сделает утопленный прямоугольник меньше... Однако, судя по вашим снимкам экрана, это то, что вам нужно.

Трекбар — это один из собственных элементов управления, поддерживающих пользовательское рисование. По сути, когда темы включены, вы можете управлять различными аспектами рисования элемента управления или можете сообщить ОС, что вы сами рисуете детали. Подробнее о пользовательском рисовании см. здесь.

Нам не нужно перегонять какой-либо рисунок, чтобы немного поиграть с размерами некоторых деталей. Именно VCL рисует канал (углубленный фон трекинга) и такты. Для тиков уже есть свойства, которые мы можем использовать. Для канала мы можем немного сдуть прямоугольник, и VCL возьмет на себя управление. Ползунок рисуется оконной процедурой по умолчанию, но это не имеет значения, ОС отрисовывает бегунок в измененный прямоугольник.

В приведенном ниже примере (для горизонтального трекбара) перехватывается уведомление WM_NOTIFY, отправленное в форму, для выполнения этих изменений. Это будет работать только в том случае, если трекбар размещен непосредственно на форме. Если это не так, вы можете получить новый элемент управления, производный от TTrackBar, для обработки CN_NOTIFY, или создать подкласс элемента управления или его родителя для WM_NOTIFY. Все, что имеет значение, — это обработать уведомление до того, как будет выполнено фактическое рисование.

Вот как выглядит пример:

type
  TForm1 = class(TForm)
    Button1: TButton;
    TrackBar1: TTrackBar;
    procedure FormCreate(Sender: TObject);
  protected
    procedure WMNotify(var Msg: TWMNotify); message WM_NOTIFY;
  end;

...

uses
  themes, commctrl, xpman;

{$R *.dfm}

procedure TForm1.FormCreate(Sender: TObject);
begin
  if ThemeServices.ThemesEnabled and
      (TrackBar1.Orientation = trHorizontal) then begin
    TrackBar1.TickMarks := tmBoth;
    TrackBar1.TickStyle := tsNone;
    TrackBar1.ThumbLength := 38;
  end;
end;

procedure TForm1.WMNotify(var Msg: TWMNotify);
begin
  if ThemeServices.ThemesEnabled and
      (TrackBar1.Orientation = trHorizontal) then begin

    if (Msg.IDCtrl = Longint(TrackBar1.Handle)) and
        (Msg.NMHdr.code = NM_CUSTOMDRAW) and
        (PNMCustomDraw(Msg.NMHdr).dwDrawStage = CDDS_ITEMPREPAINT) then begin

      case PNMCustomDraw(Msg.NMHdr).dwItemSpec of
        TBCD_THUMB: InflateRect(PNMCustomDraw(Msg.NMHdr).rc, -4, 0);
        TBCD_CHANNEL:
          with PNMCustomDraw(Msg.NMHdr).rc do begin
            Top := Bottom div 2 + 2;
            Bottom := Top + 5;
            Inc(Left, 4);
            Dec(Right, 4);
          end;
      end;
    end;
  end;

  inherited;
end;