Как вы просматриваете каждую строку в текстовом файле с помощью командного файла Windows?

Из справочника командной строки Windows:

Чтобы проанализировать файл, игнорируя закомментированные строки, введите:

for /F "eol=; tokens=2,3* delims=," %i in (myfile.txt) do @echo %i %j %k

Эта команда анализирует каждую строку в Myfile.txt, игнорируя строки, начинающиеся с точки с запятой, и передает второй и третий токены из каждой строки в тело FOR (токены разделяются запятыми или пробелами). В теле оператора FOR содержится ссылка на% i для получения второго токена, на% j для получения третьего токена и на% k для получения всех оставшихся токенов.

Если указанные вами имена файлов содержат пробелы, заключите текст в кавычки (например, «Имя файла»). Чтобы использовать кавычки, вы должны использовать usebackq. В противном случае кавычки интерпретируются как определение литеральной строки для синтаксического анализа.

Кстати, вы можете найти файл справки командной строки в большинстве систем Windows по адресу:

 "C:\WINDOWS\Help\ntcmds.chm"

В пакетном файле вы ДОЛЖНЫ использовать %% вместо %: (введите help for)

for /F "tokens=1,2,3" %%i in (myfile.txt) do call :process %%i %%j %%k
goto thenextstep
:process
set VAR1=%1
set VAR2=%2
set VAR3=%3
COMMANDS TO PROCESS INFORMATION
goto :EOF

Что это делает: «do call: process %% i %% j %% k» в конце команды for передает информацию, полученную в команде for, из myfile.txt в подпрограмму «process».

Когда вы используете команду for в пакетной программе, вам нужно использовать двойные знаки% для переменных.

Следующие строки передают эти переменные из команды for в подпрограмму процесса и позволяют обрабатывать эту информацию.

set VAR1=%1
 set VAR2=%2
 set VAR3=%3

У меня есть несколько довольно продвинутых вариантов использования этой точной настройки, которыми я готов поделиться, если потребуются дополнительные примеры. Конечно, добавьте EOL или Delims по мере необходимости.

Улучшение первого ответа «FOR / F ..»: мне нужно было вызвать execute каждый скрипт, указанный в MyList.txt, так что у меня это сработало:

for /F "tokens=*" %A in  (MyList.txt) do CALL %A ARG1

--ИЛИ, если вы хотите сделать это на нескольких строках:

for /F "tokens=*" %A in  (MuList.txt) do (
ECHO Processing %A....
CALL %A ARG1
)

Изменить: приведенный выше пример предназначен для выполнения цикла FOR из командной строки; из пакетного сценария необходимо добавить дополнительный%, как показано ниже:

---START of MyScript.bat---
@echo off
for /F "tokens=*" %%A in  ( MyList.TXT) do  (
   ECHO Processing %%A.... 
   CALL %%A ARG1 
)
@echo on
;---END of MyScript.bat---

ответ @ MrKraus поучителен. Кроме того, позвольте мне добавить, что если вы хотите загрузить файл, расположенный в том же каталоге, что и пакетный файл, добавьте к имени файла префикс% ~ dp0. Вот пример:

cd /d %~dp0
for /F "tokens=*" %%A in (myfile.txt) do [process] %%A

NB:: если ваше имя файла или каталог (например, myfile.txt в приведенном выше примере) имеет пробел (например, my file.txt или c: \ Program Files), используйте:

for /F "tokens=*" %%A in ('type "my file.txt"') do [process] %%A

с ключевым словом type, вызывающим type программу, отображающую содержимое текстового файла. Если вы не хотите тратить время на вызов команды type, вам следует сменить каталог на каталог текстового файла. Обратите внимание, что тип по-прежнему требуется для имен файлов с пробелами.

Я надеюсь, что это помогает кому-то!

Принятый ответ хорош, но имеет два ограничения.
Он отбрасывает пустые строки и строки, начинающиеся с ;

Чтобы читать строки любого контента, вам понадобится техника переключения отложенного раскрытия.

@echo off
SETLOCAL DisableDelayedExpansion
FOR /F "usebackq delims=" %%a in (`"findstr /n ^^ text.txt"`) do (
    set "var=%%a"
    SETLOCAL EnableDelayedExpansion
    set "var=!var:*:=!"
    echo(!var!
    ENDLOCAL
)

Findstr используется для добавления к каждой строке номера строки и двоеточия, чтобы пустые строки больше не были пустыми.

DelayedExpansion необходимо отключить при доступе к параметру %%a, иначе восклицательные знаки ! и вставки ^ будут потеряны, поскольку в этом режиме они имеют особое значение.

Но чтобы удалить номер строки из строки, необходимо включить отложенное раскрытие.
set "var=!var:*:=!" удаляет все до первого двоеточия (использование delims=: удалит также все двоеточия в начале строки, а не только один из findstr ).
endlocal снова отключает отложенное раскрытие для следующей строки.

Единственное ограничение - теперь ограничение длины строки ~ 8191, но, похоже, нет никакого способа преодолеть это.

Или вы можете исключить варианты в кавычках:

FOR /F %%i IN (myfile.txt) DO ECHO %%i

Вот файл bat, который я написал для выполнения всех сценариев SQL в папке:

REM ******************************************************************
REM Runs all *.sql scripts sorted by filename in the current folder.
REM To use integrated auth change -U <user> -P <password> to -E
REM ******************************************************************

dir /B /O:n *.sql > RunSqlScripts.tmp
for /F %%A in (RunSqlScripts.tmp) do osql -S (local) -d DEFAULT_DATABASE_NAME -U USERNAME_GOES_HERE -P PASSWORD_GOES_HERE -i %%A
del RunSqlScripts.tmp

Если у вас Windows семейства NT (с cmd.exe в качестве оболочки), попробуйте команду FOR / F.

Принятый ответ, использующий cmd.exe и

for /F "tokens=*" %F in (file.txt) do whatever "%F" ...

работает только для "обычных" файлов. С огромными файлами он терпит неудачу.

Для больших файлов вам может потребоваться Powershell и что-то вроде этого:

[IO.File]::ReadLines("file.txt") | ForEach-Object { whatever "$_" }

или если у вас достаточно памяти:

foreach($line in [System.IO.File]::ReadLines("file.txt")) { whatever "$line" } 

Это сработало для меня с файлом 250 МБ, содержащим более 2 миллионов строк, где команда for /F ... застряла после нескольких тысяч строк.

О различиях между foreach и ForEach-Object см. Знакомство с ForEach и ForEach-Object.

(кредиты: Построчное чтение файла в PowerShell)

Модифицированные примеры здесь, чтобы перечислить наши приложения Rails на Heroku - спасибо!

cmd /C "heroku list > heroku_apps.txt"
find /v "=" heroku_apps.txt | find /v ".TXT" | findstr /r /v /c:"^$" > heroku_apps_list.txt
for /F "tokens=1" %%i in (heroku_apps_list.txt) do heroku run bundle show rails --app %%i

Полный код здесь.

Чтобы распечатать все строки текстового файла из командной строки (с delayedExpansion):

set input="path/to/file.txt"

for /f "tokens=* delims=[" %i in ('type "%input%" ^| find /v /n ""') do (
set a=%i
set a=!a:*]=]!
echo:!a:~1!)

Работает с ведущими пробелами, пустыми строками, пробельными строками.

Проверено на Win 10 CMD