Это решило мою проблему: использование applicationVariants.all вместо applicationVariants.each

buildTypes {
      release {
        signingConfig signingConfigs.release
        applicationVariants.all { variant ->
            def file = variant.outputFile
            variant.outputFile = new File(file.parent, file.name.replace(".apk", "-" + defaultConfig.versionName + ".apk")) 
        }
    }       
}

Обновлять:

Кажется, это не работает с версиями 0.14+ плагина android studio gradle.

Это помогает (ссылка из этого вопрос):

android {
    applicationVariants.all { variant ->
        variant.outputs.each { output ->
            output.outputFile = new File(
                    output.outputFile.parent,
                    output.outputFile.name.replace(".apk", "-${variant.versionName}.apk"))
        }
    }
}

(ИЗМЕНЕНО для работы с Android Studio 3.0 и Gradle 4)

Я искал более сложную опцию переименования файлов apk, и я написал ее в надежде, что она будет полезна для всех остальных. Он переименовывает apk со следующими данными:

• аромат
• тип сборки
• версия
• дата

Мне потребовалось небольшое исследование классов gradle и немного копирования / вставки из других ответов. Я использую gradle 3.1.3.

В build.gradle:

android {

    ...

    buildTypes {
        release {
            minifyEnabled true
            ...
        }
        debug {
            minifyEnabled false
        }
    }

    productFlavors {
        prod {
            applicationId "com.feraguiba.myproject"
            versionCode 3
            versionName "1.2.0"
        }
        dev {
            applicationId "com.feraguiba.myproject.dev"
            versionCode 15
            versionName "1.3.6"
        }
    }

    applicationVariants.all { variant ->
        variant.outputs.all { output ->
            def project = "myProject"
            def SEP = "_"
            def flavor = variant.productFlavors[0].name
            def buildType = variant.variantData.variantConfiguration.buildType.name
            def version = variant.versionName
            def date = new Date();
            def formattedDate = date.format('ddMMyy_HHmm')

            def newApkName = project + SEP + flavor + SEP + buildType + SEP + version + SEP + formattedDate + ".apk"

            outputFileName = new File(newApkName)
        }
    }
}

Если вы скомпилируете сегодня (13-10-2016) в 10:47, вы получите следующие имена файлов в зависимости от выбранного вами вкуса и типа сборки:

• отладка разработчика: myProject_ dev_debug_1.3.6 _131016_1047.apk
• выпуск для разработчиков: myProject_ dev_release_1.3.6 _131016_1047.apk
• отладка prod: myProject_ prod_debug_1.2.0 _131016_1047.apk
• выпуск продукта: myProject_ prod_release_1.2.0 _131016_1047.apk

Примечание: имя apk невыровненной версии по-прежнему используется по умолчанию.

Подводя итог, для тех, кто не знает, как импортировать пакет в build.gradle (например, я), используйте следующие buildTypes,

buildTypes {
      release {
        signingConfig signingConfigs.release
        applicationVariants.all { variant ->
            def file = variant.outputFile
            def manifestParser = new com.android.builder.core.DefaultManifestParser()
            variant.outputFile = new File(file.parent, file.name.replace(".apk", "-" + manifestParser.getVersionName(android.sourceSets.main.manifest.srcFile) + ".apk")) 
        }
    }       
}

===== РЕДАКТИРОВАТЬ =====

Если вы установите свои versionCode и versionName в своем build.gradle файле следующим образом:

defaultConfig {
    minSdkVersion 15
    targetSdkVersion 19
    versionCode 1
    versionName "1.0.0"
}

Вы должны установить это так:

buildTypes {   
        release {
            signingConfig signingConfigs.releaseConfig
            applicationVariants.all { variant ->
                def file = variant.outputFile
                variant.outputFile = new File(file.parent, file.name.replace(".apk", "-" + defaultConfig.versionName + ".apk"))
            }
        }
}

====== РЕДАКТИРОВАТЬ в Android Studio 1.0 ======

Если вы используете Android Studio 1.0, вы получите такую ​​ошибку:

Error:(78, 0) Could not find property 'outputFile' on com.android.build.gradle.internal.api.ApplicationVariantImpl_Decorated@67e7625f.

Вы должны изменить часть build.Types на это:

buildTypes {
        release {
            signingConfig signingConfigs.releaseConfig
            applicationVariants.all { variant ->
                variant.outputs.each { output ->
                    output.outputFile = new File(output.outputFile.parent, output.outputFile.name.replace(".apk", "-" + defaultConfig.versionName + ".apk"))
                }
            }
        }
    }

Если вы не укажете versionName в блоке defaultConfig, тогда defaultConfig.versionName приведет к null

чтобы получить versionName из манифеста, вы можете написать следующий код в build.gradle:

import com.android.builder.DefaultManifestParser

def manifestParser = new DefaultManifestParser()
println manifestParser.getVersionName(android.sourceSets.main.manifest.srcFile)

В моем случае я просто хотел найти способ автоматизировать генерацию разных apk имен для вариантов release и debug. Мне удалось это легко сделать, поместив этот фрагмент в качестве дочернего элемента android:

applicationVariants.all { variant ->
    variant.outputs.each { output ->
        def appName = "My_nice_name_"
        def buildType = variant.variantData.variantConfiguration.buildType.name
        def newName
        if (buildType == 'debug'){
            newName = "${appName}${defaultConfig.versionName}_dbg.apk"
        } else {
            newName = "${appName}${defaultConfig.versionName}_prd.apk"
        }
        output.outputFile = new File(output.outputFile.parent, newName)
    }
}

Для нового плагина Android Gradle 3.0.0 вы можете сделать что-то вроде этого:

 applicationVariants.all { variant ->
    variant.outputs.all {
        def appName = "My_nice_name_"
        def buildType = variant.variantData.variantConfiguration.buildType.name
        def newName
        if (buildType == 'debug'){
            newName = "${appName}${defaultConfig.versionName}_dbg.apk"
        } else {
            newName = "${appName}${defaultConfig.versionName}_prd.apk"
        }
        outputFileName = newName
    }
}

Это производит что-то вроде: My_nice_name_3.2.31_dbg.apk

Gradle 6+

Сейчас я использую в Android Studio 4.0 и Gradle 6.4 следующее:

android {
    defaultConfig {
        applicationId "com.mycompany.myapplication"
        minSdkVersion 21
        targetSdkVersion 29
        versionCode 15
        versionName "2.1.1"
    }
    buildTypes {
        release {
            minifyEnabled false
            proguardFiles getDefaultProguardFile('proguard-android.txt'), 'proguard-rules.pro'
            applicationVariants.all { variant ->
                variant.outputs.all {
                    outputFileName = "ApplicationName-${variant.name}-${variant.versionName}.apk"
                }
            }
        }
    }
}

Gradle 4

Синтаксис немного изменился в Gradle 4 (Android Studio 3+) (с output.outputFile на outputFileName, идея из этот ответ сейчас :

android {
    applicationVariants.all { variant ->
        variant.outputs.each { output ->
            def newName = outputFileName
            newName.replace(".apk", "-${variant.versionName}.apk")
            outputFileName = new File(newName)
        }
    }
}

Другой альтернативой является использование следующего:

String APK_NAME = "appname"
int VERSION_CODE = 1
String VERSION_NAME = "1.0.0"

project.archivesBaseName = APK_NAME + "-" + VERSION_NAME;

    android {
      compileSdkVersion 21
      buildToolsVersion "21.1.1"

      defaultConfig {
        applicationId "com.myapp"
        minSdkVersion 15
        targetSdkVersion 21
        versionCode VERSION_CODE
        versionName VERSION_NAME
      }

       .... // Rest of your config
}

Это установит "appname-1.0.0" для всех ваших выходных файлов apk.

Правильный способ переименовать apk в соответствии с ответом @Jon

defaultConfig {
        applicationId "com.irisvision.patientapp"
        minSdkVersion 24
        targetSdkVersion 22
        versionCode 2  // increment with every release
        versionName "0.2" // change with every release
        testInstrumentationRunner "android.support.test.runner.AndroidJUnitRunner"
        //add this line
        archivesBaseName = "AppName-${versionName}-${new Date().format('yyMMdd')}"
    }   

Или другим способом вы можете добиться тех же результатов с помощью

android {
    ...

    compileOptions {
        sourceCompatibility JavaVersion.VERSION_1_8
        targetCompatibility JavaVersion.VERSION_1_8
    }

    applicationVariants.all { variant ->
        variant.outputs.all { output ->
            def formattedDate = new Date().format('yyMMdd')
            outputFileName = "${outputFileName.replace(".apk","")}-v${defaultConfig.versionCode}-${formattedDate}.apk"
        }
    }
}

Есть много ответов, которые верны либо полностью, либо после некоторых модификаций. Но я все равно добавлю свой, так как у меня была проблема со всеми из них, потому что я использовал скрипты для динамической генерации VersionName и VersionCode путем подключения к задаче preBuild.

Если вы используете аналогичный подход, это код, который будет работать:

project.android.applicationVariants.all { variant ->
    variant.preBuild.doLast {
    variant.outputs.each { output ->
        output.outputFile = new File(
                output.outputFile.parent,
                output.outputFile.name.replace(".apk", "-${variant.versionName}@${variant.versionCode}.apk"))
        }
    }
}

Чтобы объяснить: поскольку я переопределяю код версии и имя в первом действии preBuild, я должен добавить переименование файла в конец этой задачи. Итак, что Gradle будет делать в этом случае:

Ввести код версии / имя-> выполнить действия перед сборкой -> заменить имя для apk

В моем случае я решаю эту ошибку таким образом

добавление SUFFIX в версию Debug, в этом случае я добавляю текст «-DEBUG» к моему развертыванию Debug

 buildTypes {
        release {

            signingConfig signingConfigs.release
            minifyEnabled false
            proguardFiles getDefaultProguardFile('proguard-android.txt'), 'proguard-rules.pro'


        }
        debug {

            defaultConfig {
                debuggable true

                versionNameSuffix "-DEBUG"
            }
        }
    }

Для последних версий Gradle вы можете использовать следующий фрагмент:

Сначала укажите местоположение манифеста вашего приложения

 sourceSets {
        main {
            manifest.srcFile 'src/main/AndroidManifest.xml'
        {
    }

А позже в build.gradle

import com.android.builder.core.DefaultManifestParser

def getVersionName(manifestFile) {
    def manifestParser = new DefaultManifestParser();
    return manifestParser.getVersionName(manifestFile);
}

def manifestFile = file(android.sourceSets.main.manifest.srcFile);
def version = getVersionName(manifestFile)

buildTypes {
    release {
       signingConfig signingConfigs.release
       applicationVariants.each { variant ->
       def file = variant.outputFile
       variant.outputFile = new File(file.parent, file.name.replace(".apk", "-" +    versionName + ".apk"))
    }
}

Отрегулируйте, если у вас разные манифесты для каждого типа сборки. но так как у меня один - у меня отлично работает.

Что касается Android Studio 1.1.0, я обнаружил, что эта комбинация работает в теле android файла build.gradle. Это если вы не можете понять, как импортировать данные XML-файла манифеста. Хотелось бы, чтобы это больше поддерживалось Android Studio, но просто поиграйте со значениями, пока не получите желаемое имя apk:

defaultConfig {
        applicationId "com.package.name"
        minSdkVersion 14
        targetSdkVersion 21
        versionCode 6
        versionName "2"
    }
    signingConfigs {
        release {
            keyAlias = "your key name"
        }
    }
    buildTypes {
        release {
            minifyEnabled true
            proguardFiles getDefaultProguardFile('proguard-android.txt'), 'proguard-rules.pro'

            signingConfig signingConfigs.release
            applicationVariants.all { variant ->
                variant.outputs.each { output ->
                    output.outputFile = new File(output.outputFile.parent, output.outputFile.name.replace("app-release.apk", "appName_" + versionName + ".apk"))
                }
            }
        }
    }

Как я ответил, здесь Если вы хотите добавить название версии и код версии в выходной файл, сделайте это так:

applicationVariants.all { variant ->
        variant.outputs.all {
            def versionName = variant.versionName
            def versionCode = variant.versionCode
            def variantName = variant.name
            outputFileName = "${rootProject.name}" + '_' + variantName + '_' + versionName + '_' + versionCode + '.apk'
        }
    }

Вы также можете добавить отформатированное время сборки к имени apk, как показано ниже:

setProperty("archivesBaseName", "data-$versionName " + (new Date().format("HH-mm-ss")))