Как объявить глобальную переменную в VBA?

Вам нужно объявить переменные вне функции:

Public iRaw As Integer
Public iColumn As Integer

Function find_results_idle()
    iRaw = 1
    iColumn = 1

Это вопрос о области действия.

Если вы хотите, чтобы переменные действовали только в течение всего времени существования функции, используйте Dim (сокращение от Dimension) внутри функции или подпрограммы для объявления переменных:

Function AddSomeNumbers() As Integer
    Dim intA As Integer
    Dim intB As Integer
    intA = 2
    intB = 3
    AddSomeNumbers = intA + intB
End Function
'intA and intB are no longer available since the function ended

глобальная переменная (как указал SLaks) объявляется вне функции с использованием ключевого слова Public. Эта переменная будет доступна в течение всего срока службы вашего запущенного приложения. В случае Excel это означает, что переменные будут доступны, пока открыта конкретная книга Excel.

Public intA As Integer
Private intB As Integer

Function AddSomeNumbers() As Integer
    intA = 2
    intB = 3
    AddSomeNumbers = intA + intB
End Function
'intA and intB are still both available.  However, because intA is public,  '
'it can also be referenced from code in other modules. Because intB is private,'
'it will be hidden from other modules.

Вы также можете иметь переменные, которые доступны только в определенном модуле (или классе), объявив их с помощью ключевого слова Private.

Если вы создаете большое приложение и чувствуете необходимость использовать глобальные переменные, я бы рекомендовал создать отдельный модуль только для ваших глобальных переменных. Это должно помочь вам отслеживать их в одном месте.

Чтобы использовать глобальные переменные, вставьте новый модуль из пользовательского интерфейса проекта VBA и объявите переменные с помощью Global

Global iRaw As Integer
Global iColumn As Integer

Вопрос действительно в размахе, как выразился другой парень.

Вкратце, рассмотрим этот «модуль»:

Public Var1 As variant     'Var1 can be used in all
                           'modules, class modules and userforms of 
                           'thisworkbook and will preserve any values
                           'assigned to it until either the workbook
                           'is closed or the project is reset.

Dim Var2 As Variant        'Var2 and Var3 can be used anywhere on the
Private Var3 As Variant    ''current module and will preserve any values
                           ''they're assigned until either the workbook
                           ''is closed or the project is reset.

Sub MySub()                'Var4 can only be used within the procedure MySub
    Dim Var4 as Variant    ''and will only store values until the procedure 
End Sub                    ''ends.

Sub MyOtherSub()           'You can even declare another Var4 within a
    Dim Var4 as Variant    ''different procedure without generating an
End Sub                    ''error (only possible confusion). 

Вы можете ознакомиться с этим справочником MSDN для получения дополнительной информации об объявлении переменной и этом другом заголовке Вопрос о переполнении стека для получения дополнительной информации о том, как переменные выходят за пределы области видимости.

Еще две быстрые вещи:

1. Будьте организованы при использовании переменных уровня книги, чтобы не запутать ваш код. Отдайте предпочтение функциям (с правильными типами данных) или передаче аргументов ByRef.
2. Если вы хотите, чтобы переменная сохраняла свое значение между вызовами, вы можете использовать оператор Static.

Если эта функция находится в модуле / классе, вы можете просто написать их вне функции, так что у нее будет Global Scope. Глобальная область действия означает, что переменная может быть доступна другой функции в том же модуле / классе (если вы используете dim как оператор объявления, используйте public, если хотите, чтобы переменные были доступны для всех функций во всех модулях) :

Dim iRaw As Integer
Dim iColumn As Integer

Function find_results_idle()
    iRaw = 1
    iColumn = 1
End Function

Function this_can_access_global()
    iRaw = 2
    iColumn = 2
End Function

Также вы можете использовать -

Private Const SrlNumber As Integer = 910

Private Sub Workbook_Open()
    If SrlNumber > 900 Then
        MsgBox "This serial number is valid"
    Else
        MsgBox "This serial number is not valid"
    End If
End Sub

Протестировано в Office 2010

Создайте публичное целое число в Общей декларации.

Затем в своей функции вы можете каждый раз увеличивать ее значение. См. Пример (функция сохранения вложений электронного письма в формате CSV).

Public Numerator As Integer

Public Sub saveAttachtoDisk(itm As Outlook.MailItem)
Dim objAtt As Outlook.Attachment
Dim saveFolder As String
Dim FileName As String

saveFolder = "c:\temp\"

     For Each objAtt In itm.Attachments
            FileName = objAtt.DisplayName & "_" & Numerator & "_" & Format(Now, "yyyy-mm-dd H-mm-ss") & ".CSV"
                      objAtt.SaveAsFile saveFolder & "\" & FileName
                      Numerator = Numerator + 1

          Set objAtt = Nothing
     Next
End Sub

Хороший способ создания общедоступных / глобальных переменных - рассматривать форму как объект класса, объявлять свойства и использовать Public Property Get [переменная] для доступа к свойству / методу. Также вам может потребоваться указать или передать ссылку на созданный модуль формы. Вы получите ошибки, если вызовете методы для закрытых форм / отчетов.
Пример: передайте Me.Form.Module.Parent в подпункт / функцию не внутри формы.

Option Compare Database 
Option Explicit
''***********************************''
' Name: Date: Created Date Author: Name 
' Current Version: 1.0
' Called by: 
''***********************************''
' Notes: Explain Who what when why... 
' This code Example requires properties to be filled in 
''***********************************''
' Global Variables
Public GlobalData As Variant
''***********************************''
' Private Variables
Private ObjectReference As Object
Private ExampleVariable As Variant
Private ExampleData As Variant
''***********************************''
' Public properties
Public Property Get ObjectVariable() As Object
   Set ObjectVariable = ObjectReference
End Property 
Public Property Get Variable1() As Variant 
  'Recommend using variants to avoid data errors
  Variable1 = ExampleVariable
End property
''***********************************''
' Public Functions that return values
Public Function DataReturn (Input As Variant) As Variant
   DataReturn = ExampleData + Input
End Function 
''***********************************''
' Public Sub Routines
Public Sub GlobalMethod() 
   'call local Functions/Subs outside of form
   Me.Form.Refresh
End Sub
''***********************************''
' Private Functions/Subs used not visible outside 
''***********************************''
End Code

Таким образом, в другом модуле вы сможете получить доступ:

Public Sub Method1(objForm as Object)
   'read/write data value
   objForm.GlobalData
   'Get object reference (need to add Public Property Set to change reference object)
   objForm.ObjectVariable
   'read only (needs Public property Let to change value)
   objForm.Variable1
   'Gets result of function with input
   objForm.DataReturn([Input])
   'runs sub/function from outside of normal scope
   objForm.GlobalMethod
End Sub

Если вы используете Late Binding, как я, всегда проверяю значения Null и объекты, которые Nothing, прежде чем пытаться выполнить какую-либо обработку.