Как я могу изменить регистр хеш-ключа?

Ответ Энди - хороший ответ, за исключением того, что он ucs каждый ключ, а затем ucs его снова, если он не совпадает.

Это uc раз:

%hash = map { uc $_ => $hash{$_} } keys %hash;

Но поскольку вы упомянули о пользователях, хранящих ключи, связка является гораздо более надежным способом, хотя и медленнее.

package UCaseHash;
require Tie::Hash;

our @ISA = qw<Tie::StdHash>;

sub FETCH { 
    my ( $self, $key ) = @_;
    return $self->{ uc $key };
}

sub STORE { 
    my ( $self, $key, $value ) = @_;
    $self->{ uc $key } = $value;
}

1;

И затем в основном:

tie my %hash, 'UCaseHash'; 

Это шоу. «Магия» tie инкапсулирует его, поэтому пользователи не могут неосознанно с ним связываться.

Конечно, пока вы используете «класс», вы можете передать имя файла конфигурации и инициализировать его оттуда:

package UCaseHash;
use Tie::Hash;
use Carp qw<croak>;

...

sub TIEHASH { 
    my ( $class_name, $config_file_path ) = @_;
    my $self = $class_name->SUPER::TIEHASH;
    open my $fh, '<', $config_file_path 
        or croak "Could not open config file $config_file_path!"
        ;
    my %phash = _process_config_lines( <$fh> );
    close $fh;
    $self->STORE( $_, $phash{$_} ) foreach keys %phash;
    return $self;
}

Где вы должны были бы назвать это так:

tie my %hash, 'UCaseHash', CONFIG_FILE_PATH;

...при условии некоторой константы CONFIG_FILE_PATH.

Пройдитесь по хэшу и замените все клавиши в нижнем регистре их эквивалентами в верхнем регистре и удалите старые. Грубо:

for my $key ( grep { uc($_) ne $_ } keys %hash ) {
    my $newkey = uc $key;
    $hash{$newkey} = delete $hash{$key};
}

Это преобразует многоуровневый хеш в нижний регистр

my $lowercaseghash = convertmaptolowercase(\%hash);

sub convertmaptolowercase(){
    my $output=$_[0];
    while(my($key,$value) = each(%$output)){
        my $ref;
        if(ref($value) eq "HASH"){
            $ref=convertmaptolowercase($value);
        } else {
           $ref=$value;
        }
        delete $output->{$key}; #Removing the existing key
        $key = lc $key;
        $output->{$key}=$ref; #Adding new key
    }
    return $output;
}