Как я могу назначить вариант варианту в VBA?

В VBA единственный способ присвоить Variant переменной, когда вы не знаете, является ли она объектом или примитивом, — это передать ее в качестве параметра.

Если вы не можете реорганизовать свой код так, чтобы v передавалось в качестве параметра свойству Sub, Function или Let (несмотря на Let, это также работает с объектами), вы всегда можете объявить v в области модуля и иметь выделенный Sub исключительно для цель сохранения-назначения этой переменной:

Private v As Variant

Private Sub SetV(ByVal var As Variant)
    If IsObject(var) Then
        Set v = var
    Else
        v = var
    End If
End Sub

где-то еще звонит SetV SomeMethod().

Некрасиво, но это единственный способ не вызывать SomeMethod() дважды и не трогать его внутреннюю работу.

Редактировать

Хорошо, я обдумал это и думаю, что нашел лучшее решение, которое ближе всего к тому, что вы имели в виду:

Public Sub LetSet(ByRef variable As Variant, ByVal value As Variant)
    If IsObject(value) Then
        Set variable = value
    Else
        variable = value
    End If
End Sub

[...] Я думаю, что в VBA просто нет оператора LetSet v = ...

Теперь есть: LetSet v, SomeMethod()

У вас нет возвращаемого значения, которое вам нужно Let или Set для переменной в зависимости от ее типа, вместо этого вы передаете переменную, которая должна содержать возвращаемое значение, в качестве первого параметра по ссылке, чтобы Sub может изменить свое значение.

Вы можете использовать перехват ошибок, чтобы уменьшить ожидаемое количество вызовов методов. Сначала попробуй поставить. Если получится - не беда. В противном случае просто назначьте:

Public counter As Long

Function Ambiguous(b As Boolean) As Variant
    counter = counter + 1
    If b Then
        Set Ambiguous = ActiveSheet
    Else
        Ambiguous = 1
    End If
End Function

Sub test()
    Dim v As Variant
    Dim i As Long, b As Boolean

    Randomize
    counter = 0
    For i = 1 To 100
        b = Rnd() < 0.5
        On Error Resume Next
            Set v = Ambiguous(b)
            If Err.Number > 0 Then
                Err.Clear
                v = Ambiguous(b)
            End If
        On Error GoTo 0
    Next i
    Debug.Print counter / 100

End Sub

Когда я запустил код, в первый раз я получил 1,55, что меньше, чем 2,00, которые вы получили бы, если бы повторили эксперимент, но с заменой подхода обработки ошибок на наивный подход if-then-else, который вы обсуждали в своем вопросе.

Обратите внимание, что чем чаще функция возвращает объект, тем меньше вызовов функции в среднем. Если он почти всегда возвращает объект (например, это то, что он должен возвращать, но в некоторых случаях возвращает строку, описывающую состояние ошибки), то этот способ выполнения действий будет приближаться к 1 вызову на настройку/назначение переменной. С другой стороны - если он почти всегда возвращает примитивное значение, то вы приблизитесь к 2 вызовам на одно назначение - и в этом случае, возможно, вам следует реорганизовать свой код.

Похоже, я не t единственный с этой проблемой.

Решение было дано мне здесь.

Короче:

Public Declare Sub VariantCopy Lib "oleaut32.dll" (ByRef pvargDest As Variant, ByRef pvargSrc As Variant)
Sub Main()
  Dim v as Variant
  VariantCopy v, SomeMethod()
end sub

Кажется, это похоже на функцию LetSet(), описанную в ответе, но я решил, что это все равно будет полезно.