Zip-файлы в .Net 4.5 без сторонних библиотек

Я хочу создать zip-папку и добавить существующие файлы (в данном случае документы) в .zip-папку, возможно ли это?

Да, это возможно. Для начала вам нужно добавить несколько ссылок на ваш проект.

• System.IO.Compression
• System.IO.Compression.FileSystem

Затем добавьте эти Import операторы в свой файл класса.

 Imports System.IO
 Imports System.IO.Compression

Для этого я использовал событие нажатия кнопки, но вы можете поместить его куда угодно ...

Private Sub Button1_Click(sender As Object, e As EventArgs) Handles Button1.Click
        Using modFile As ZipArchive = ZipFile.Open("ZIP PATH HERE", ZipArchiveMode.Update)
            modFile.CreateEntryFromFile("FILE YOU WANT TO ADD", "ENTRY NAME")
        End Using
    End Sub

Для более простого использования, если вы хотите заархивировать все файлы, содержащиеся в существующей папке.

Это проще, потому что вам не нужно указывать полное имя файла, он просто берет все файлы, найденные в папке. Однако вы должны указать расширение «.zip» в имени файла «destination_file.zip».

Как указано в другом ответе, вам нужно добавить две ссылки в свой проект.

1. System.IO.Compression
2. System.IO.Compression.FileSystem

И добавьте эти операторы импорта в свой файл класса.

 Imports System.IO
 Imports System.IO.Compression

Вот код для процедуры нажатия кнопки, его можно поместить в другое место. Как видите, это всего лишь одна строка кода.

Private Sub Button1_Click(sender As Object, e As EventArgs) Handles Button1.Click
    ZipFile.CreateFromDirectory("Folder you want to zip",
                                "destination_file.zip",
                                 CompressionLevel.Optimal,
                                 False)
End Sub

Но похоже, что вы хотите отправить выбранные файлы в архив .zip.

Допустим, у вас есть элемент управления DataGridView с именем dgv1, заполненный несколькими строками данных, и вы несколько раз выбрали несколько из этих строк, а полный путь / имя файла находится в первом столбце DataGridView .

Существует вспомогательная функция (selectedList ()) для форматирования выбранных ячеек из datagridview в список с полными путями / именами файлов.

Функция zipEm () берет список файлов и имя целевого файла архива и создает файл .zip.

Подпрограмма Button1_Click () вызывает первые две подпрограммы и предоставляет пользователю обратную связь.

        ' returns list of items from column col that are selected
Function selectedList(dgv1 As DataGridView, col As Integer) As List(Of String)
    selectedList = New List(Of String)
    For Each cell As DataGridViewCell In dgv1.SelectedCells
        If cell.ColumnIndex = col Then selectedList.Add(cell.Value.ToString())
    Next
End Function

' archives a list of files to the designated file (overwriting, if it already exists)
Function zipEm(fileList As List(Of String), nzfName As String) As Boolean
    Try
        If File.Exists(nzfName) Then File.Delete(nzfName)
        Using newZipFile As ZipArchive = ZipFile.Open(nzfName, ZipArchiveMode.Create)
            For Each pfn As String In fileList
                newZipFile.CreateEntryFromFile(pfn, Path.GetFileName(pfn))
            Next
        End Using
    Catch ex As Exception
        Return False
    End Try
    Return True
End Function

Private Sub Button1_Click(sender As Object, e As EventArgs) Handles Button1.Click
    Dim fileList As List(Of String) = selectedList(dgv1, 0)
    If fileList.Count = 0 Then
        MsgBox("No valid items selected.", vbExclamation, "'lil problem")
        Exit Sub
    End If
    Dim nzfName As String = Path.Combine(Path.GetDirectoryName(fileList(0)),
                            "sample (" & fileList.Count.ToString() & " items).zip")
    If zipEm(fileList, nzfName) Then
        MsgBox("Saved zip file containing " & fileList.Count.ToString() & " items.",
               vbOKOnly, "sucess")
    Else
        MsgBox("Unable to save .zip file.", vbExclamation, "'lil problem")
    End If
End Sub

Если вы предпочитаете накапливать файлы в архиве (вместо перезаписи), константу «ZipArchiveMode.Create» можно изменить на «ZipArchiveMode.Update» в вызове ZipFile.Open () zipEm ().