Как передать подпрограмме Perl два массива и строку?

Вам нужно передать каждый из массивов в качестве ссылки, иначе ваш @x в подпрограмме сожрет ВЕСЬ массив аргументов, оставив @y пустым массивом, а $z значением undef.

Это происходит потому, что оператор запятая в контексте списка превращает @x, @y, $z в единый массив, состоящий из всех элементов @x, за которыми следуют все элементы @y, а затем значение $z; ваш @x в подпрограмме поглотит ВЕСЬ комбинированный массив аргументов, оставив @y пустым массивом, а $z значением undef.

Еще одним возможным источником путаницы является тот факт, что вы назвали обе переменные @x, несмотря на то, что они полностью независимы друг от друга из-за правил области видимости. Хорошей практикой было бы назвать их чем-то отличным, чтобы не угадывать, какой из них вы хотели использовать, например. вызовите первый массив подпрограммы @x2.

Обратите внимание, что вы можете передать массив в качестве ссылки одним из двух способов — ссылкой на исходный массив (реальный подход передачи по ссылке), а также ссылкой на КОПИЮ массива — которая будет вести себя так, как вы хотели, чтобы ваш исходный код для поведения и передачи по значению.

use strict; use warnings;

my @x = qw(AAAA BBBB CCCC DDDD EEEE); 
my @y = qw(1111 2222 3333 4444 5555);
my $z = "hello";

Hello(\@x,\@y,$z);

# If you wish to pass a reference of a COPY of the array, 
# so that you can modify it inside the subroutine without modifying the original,
# instead call Hello([@x], [@y], $z);

exit(0);

sub Hello {

    my ($x2,$y2,$z2) = @_;
    # Now, you de-reference array reference $x2 via @$x2 or $x2->[$i]
    # where previously you used @x2 or $x2[$i]
    print "$_\n" for @$x2;
    print "$_\n";
    print "$_\n" for @$y2;
    print "$_\n";
    print "$z2\n";

}

вам нужно использовать ссылки:

sub Hello {
   my ($x, $y, $z) = @_;
   print "$_\n" for @$x;
   ...
}

Hello(\@x, \@y, $z);

вы также можете использовать прототипы подпрограмм Perl, чтобы исключить \ в месте вызова:

sub Hello (\@\@$) {...}

Hello(@x, @y, $z);

Прототип (\@\@$) сообщает компилятору, что аргументы Hello будут иметь контекст ссылки на массив в первых двух аргументах и ​​скалярный контекст в третьем аргументе. Прототипы не предназначены для проверки аргументов, они позволяют вам писать подпрограммы, которые работают как встроенные. В данном случае, как push.

Как упоминает DVK в комментарии ниже, PBP не рекомендует использовать прототипы в качестве общего правила, потому что они, как правило, используются неправильно для проверки аргументов. Я чувствую, что использование определенных особенностей прототипов (\% или \@ для наложения ссылочного контекста для множественных типов или & в качестве первого аргумента, позволяющего использовать map как синтаксис блока) оправдывает разрыв с PBP. Особенно верно, если подпрограмма используется для расширения синтаксиса Perl (вспомогательные функции, функции, которые являются просто синтаксическим сахаром...)

Вам нужно передать ссылки на массив:

sub Hello {
  my ( $x_ref, $y_ref, $z ) = @_;
  my @x = @$x_ref;
  my @y = @$y_ref;
  ...
}

Hello( \@x, \@y, $z );