Как получить доступ к тексту поиска в компоненте TCRDBGrid?

Есть ли способ получить доступ к тексту, введенному в строке поиска Devart (Core Lab) TCRDBGrid?

Я попытался реализовать событие OnKeyDown, но событие не происходило при вводе в поля поиска, а только при выборе самой сетки. Других событий, которые выглядят релевантными, нет.

Кажется, что текст входит в TEdit, который является частью TCRGridTitleEdit, который является частью TCRDBGrid, но является частным.

Есть ли способ получить текст поиска?

Пример TCFGBGrid:

+---------+------------+
| UserId  |  UserName  | <- Column titles
+---------+------------+
|[987654] | [        ] | <- Search bar (searching for UserId 987654)
+---------+------------+
| 123456  |  Wile Cau  | <- Data
+---------+------------+
|   ...   |    ...     | <- More data

Если UserId 987654 не существует, я хочу запросить что-то вроде «Создать нового пользователя 987654?» и потенциально создать новую запись с UserId, установленным на 987654.


delphi devart delphi-2007
person WileCau    schedule 22.10.2010    source источник

Ответы (1)


arrow_upward
3
arrow_downward

TCRDBGrid распространяется с исходным кодом. Вы можете изменить исходный код:

объявить тип события:

  TOnTextChanged = procedure (Sender: TObject; Text: string) of object;

добавить объявление события в класс TCRGridTitleEdit:

private 
    FOnFilterChanged: TOnTextChanged;
    FOnSearchChanged: TOnTextChanged;

public
    property OnFilterChanged: TOnTextChanged read FOnFilterChanged write FOnFilterChanged;
    property OnSearchChanged: TOnTextChanged read FOnSearchChanged write FOnSearchChanged;

вызовите это событие в процедуре ProcessEdit:

procedure TCRGridTitleEdit.ProcessEdit;
begin
  if (FActiveColumn = nil) or (CRDBGrid = nil) or not FEdit.Modified then
    Exit;

  if FAsFilter then
    with CRDBGrid do begin
      try
        TCRColumn(FActiveColumn).GetFilterExpression(FEdit.Text);
        FFilterExpressions[FActiveColumn.Index] := FEdit.Text;
        Self.Caption := FFilterExpressions[FActiveColumn.Index];
        if Assigned(FOnFilterChanged) then
          FOnFilterChanged(self, FEdit.Text);
      except
        on EConvertError do begin
          FEdit.SelectAll;
          raise;
        end;
      end;
    end
  else
    try
      with FActiveColumn.Field do
        DataSet.Locate(FieldName, {$IFDEF CLR}Variant{$ENDIF}(FEdit.Text), [loCaseInsensitive,loPartialKey]);
      if Assigned(FOnSearchChanged) then
        FOnSearchChanged(self, FEdit.Text);
    except
      on EConvertError do
        Exit;
    end;
end;

и добавьте объявление события в класс TCRDBGrid:

private
  function GetOnFilterChanged: TOnTextChanged;
  procedure SetOnFilterChanged(Value: TOnTextChanged);
  function GetOnSearchChanged: TOnTextChanged;
  procedure SetOnSearchChanged(Value: TOnTextChanged);

published
  property OnFilterChanged: TOnTextChanged read GetOnFilterChanged write SetOnFilterChanged;
  property OnSearchChanged: TOnTextChanged read GetOnSearchChanged write SetOnSearchChanged;

реализация

function TCRDBGrid.GetOnFilterChanged: TOnTextChanged;
begin
  Result := CRGridTitleEdit.OnFilterChanged;
end;

procedure TCRDBGrid.SetOnFilterChanged(Value: TOnTextChanged);
begin
  CRGridTitleEdit.OnFilterChanged := Value;
end;

function TCRDBGrid.GetOnSearchChanged: TOnTextChanged;
begin
  Result := CRGridTitleEdit.OnSearchChanged;
end;

procedure TCRDBGrid.SetOnSearchChanged(Value: TOnTextChanged);
begin
  CRGridTitleEdit.OnSearchChanged := Value;
end;
person bork    schedule 22.10.2010
comment
спасибо, что включили код в свой ответ, очень признателен :) - person WileCau; 25.10.2010