delphi читает xml-элемент

Как насчет использования простого XPATH для получения запрошенных значений?

//Link[1]/node() - выбирает первый узел "Ссылка" из всего документа, а затем выбирает первый дочерний узел любого типа. Просто так случилось, что первый дочерний узел - это безымянный узел, содержащий фактическую ссылку https.

Предполагая, что XML-документ загружен в Doc: TXMLDocument, вы можете извлечь ссылку с помощью этого кода:

(Doc.DOMDocument as IDomNodeSelect).selectNode('//Link[1]/node()').nodeValue

Вы можете найти некоторую документацию по XPath в этих примерах XPath в MSDN. Лучшую документацию можно найти в w3schools. И в довершение ко всему, вот простое (но законченное) консольное приложение, которое использует XPath для извлечения и отображения трех запрошенных значений:

program Project14;

{$APPTYPE CONSOLE}

uses
  SysUtils,
  Xmldoc,
  xmldom,
  ActiveX;

var X: TXMLDocument;
    Node: IDOMNode;
    Sel: IDomNodeSelect;

begin
  try
    CoInitialize(nil);

    X := TXMLDocument.Create(nil);
    try

      // Load XML from a string constant so I can include the exact XML sample from this
      // question into the code. Note the "SomeNode" node, it's required to make that XML
      // valid.

      X.LoadFromXML(
        '<SomeNode>'+
        '  <Link role="self">' +
        '    https://spatial.virtualearth.net/REST/v1/dataflows/Geocode/jobid' +
        '  </Link>' +
        '  <Status>Aborted</Status>' +
        '  <ErrorMessage>The data uploaded in this request was not valid.</ErrorMessage>' +
        '</SomeNode>'
      );

      // Shortcut: Keep a reference to the IDomNodeSelect interface

      Sel := X.DOMDocument as IDomNodeSelect;

      // Extract and WriteLn() the values. Painfully simple!

      WriteLn(Sel.selectNode('//Link[1]/node()').nodeValue);
      WriteLn(Sel.selectNode('//Status[1]/node()').nodeValue);
      WriteLn(Sel.selectNode('//ErrorMessage[1]/node()').nodeValue);

      ReadLn;
    finally X.Free;
    end;
  except
    on E: Exception do
      Writeln(E.ClassName, ': ', E.Message);
  end;
end.

Если XML-структура достаточно стабильна, вы можете использовать инструмент привязки XML для генерации обычных классов Delphi для доступа к xml-документу.

Взгляните на эту страницу.

Поскольку существует XML-схема для этих служб пространственных данных Bing, Самый простой способ - импортировать эту схему с помощью мастера привязки данных XML Delphi, а затем использовать сгенерированные классы и интерфейсы Delphi для получения данных из XML или помещения данных в XML.

Это похоже на то, что предлагал Йорн Э. Ангельтвейт, но его предложение использует простой XML для генерации классов.
Это нормально, если у вас нет схемы , но когда у вас есть схема, всегда лучше импортировать схему.

Есть много примеров использования мастера привязки данных XML Delphi, так что начните сначала с этого.

Если вам нужна помощь по привязке: задайте здесь новый конкретный вопрос.

Теперь вам нужно проанализировать XML-файл. В простейшем случае (вы знаете теги XML) это могло бы выглядеть так:

var
  XMLDoc: IXMLDocument;
  Node: IXMLNode;
  I: Integer;
  role, link: string;

begin
  XMLDoc:= TXMLDocument.Create(nil);
  XMLDoc.LoadFromFile(AFileName);

  for I:= 0 to XMLDoc.DocumentElement.ChildNodes.Count - 1 do begin
    Node:= XMLDoc.DocumentElement.ChildNodes[I];
    if Node.NodeType = ntElement then begin
      if Node.NodeName = 'Link' then begin
        if Node.HasAttribute('role') then
          role:= Node.Attributes['role'];
        if not VarIsNull(Node.NodeValue) then
          link:= Node.NodeValue;
[..]
      end;
    end;
  end;
end;