Как включить общий файл в VBScript (аналогично C #include)?

Платформа «Windows Script Host» (если вы хотите ее так называть) предлагает документ-оболочку XML, который добавляет функциональность по сравнению с обычными файлами vbs. Одним из них является возможность включать внешние файлы сценариев как VBscript, так и Jscript. Я никогда не углублялся в это, но я думаю, что это сделает то, что вы хотите сделать. http://msdn.microsoft.com/en-us/library/15x4407c(VS.85).aspx

Вы можете включить JavaScript, VBScript или модули других языков сценариев WScript.

Пример WSF-файла:

<job id="IncludeExample">
   <script language="JavaScript" src="sprintf.js"/>
   <script language="VBScript" src="logging.vbs"/>
   <script language="VBScript" src="iis-queryScriptMaps.vbs"/>
</job>

Если указанный выше файл называется «iis-scriptmaps.wsf», запустите его с помощью cscript.exe следующим образом:

cscript.exe  iis-scriptmaps.wsf

Вы можете создать (относительно) небольшую функцию в каждом файле, в который вы хотите включить другие файлы, следующим образом:

sub includeFile (fSpec)
    dim fileSys, file, fileData
    set fileSys = createObject ("Scripting.FileSystemObject")
    set file = fileSys.openTextFile (fSpec)
    fileData = file.readAll ()
    file.close
    executeGlobal fileData
    set file = nothing
    set fileSys = nothing
end sub

а затем использовать его для включения определенных файлов - они выполняются, как если бы они были встроенными.

includeFile "commonapi.vbi"
includeFile "dbcalls.vbi"

Он в основном открывает файл, считывает все содержимое в строку, а затем выполняет эту строку. В вызовах ввода-вывода нет обработки ошибок, поскольку такие вещи обычно выполняются один раз при запуске программы, и вы хотите потерпеть неудачу, если есть проблема, включая это.

Обратите внимание, что функцию includeFile можно сжать до:

Sub includeFile(fSpec)
    With CreateObject("Scripting.FileSystemObject")
       executeGlobal .openTextFile(fSpec).readAll()
    End With
End Sub

Или даже (если вы не против длинных очередей):

Sub includeFile(fSpec)
    executeGlobal CreateObject("Scripting.FileSystemObject").openTextFile(fSpec).readAll()
End Sub

Я знаю, что это старая тема, но я все равно публикую свой ответ, чтобы другие могли узнать, что я узнал о файлах VBS и WSF методом «проб и ошибок»:

Таким образом, чтобы иметь ту же функциональность, что и в других языках, вы можете создать один файл WSF и включить в него все свои библиотеки VBS, включая основную программу.

Что-то вроде этого :

<job id="MainProg">
  <script language="VBScript" src="Constants.vbs"/>
  <script language="VBScript" src="FileFunctions.vbs"/>
  <script language="VBScript" src="SendMail.vbs"/>
  <script language="VBScript" src="LoggingFunctions.vbs"/>
  <script language="VBScript" src="MainProgram.vbs"/>   
  <script language="VBScript">
    ' Here we call the main program
    MainProgram()
  </script>
</job>

В Constants.vbs соберите все константы, которые вы хотите использовать позже, а в других файлах VBS определите свои функции. В основном файле программы MainProgram.vbs создайте файл sub с именем MainProgram() и напишите туда свою программу. В этой подпрограмме вы можете использовать все константы и функции, определенные в других файлах VBS.

Например :

sub MainProgram()
  ' Local variables
  Dim strMessage, strSendTo, strSubject
  ' OpenFile is a function from FileFunctions.vbs
  strMessage = OpenFile("C:\Msg\message.html")
  strSendTo = "[email protected]"
  strSubject = "Daily report - " & date
  ' SendMessage is a function from SendMail.vbs
  ' cFrom and cServer are constants from Constants.vbs
  SendMessage(cFrom, strSendTo, strSubject, strMessage, cServer)
  ' Logger is a function from LoggingFunctions.vbs
  Logger("Daily report sent - " & now())
end sub

Надеюсь, вы поняли идею, и я мог бы помочь некоторым людям писать лучшие приложения VBS :)

Основываясь на принятом ответе, вот подпрограмма включения, которая использует путь относительно местоположения скрипта вместо рабочего каталога:

Sub include( relativeFilePath ) 
    Set fso = CreateObject("Scripting.FileSystemObject")
    thisFolder = fso.GetParentFolderName( WScript.ScriptFullName ) 
    absFilePath = fso.BuildPath( thisFolder, relativeFilePath )
    executeGlobal fso.openTextFile( absFilePath ).readAll()
End Sub

Обратите внимание, что вы можете дополнительно использовать части . и .. в своем пути для включения файлов в родительские папки и т. д., и не имеет значения, откуда вы запускаете скрипт. Пример:

include "..\Lib\StringUtilities.vbs"

Этот VBScript используется локально или обслуживается в классическом стиле ASP?

Если это классический ASP, вы можете использовать для этого SSI:

<!-- #include virtual="/PathTo/MyFile.vbs" -->

Вы можете использовать функцию ExecuteGlobal для запуска произвольного кода VBS в глобальном пространстве имен. Пример можно найти здесь: http://www.source-code.biz/snippets/vbscript/5.htm

IIS 5 и более поздние версии также позволяют использовать тег script для включения других файлов из файла ASP. (Является ли ваш VBScript страницей ASP или сценарием Windows?) Вот пример:

<script language="VBScript" runat="server" src="include.asp"></script>

Поведение и правила немного отличаются от включений на стороне сервера. Примечание. Я никогда не пытался использовать этот синтаксис из классического ASP.

вы можете определенно использовать тег сценария WSF в cscript:

<script language="VBScript" src="ADOVBS.INC"/>

Если вы используете ADOVBS.inc для доступа к ADODB, обязательно удалите

<% %>

теги от ADOVBS.INC.